reserve n,m for Element of NAT;
reserve r,s for Real;
reserve z for Complex;
reserve CNS,CNS1,CNS2 for ComplexNormSpace;
reserve RNS for RealNormSpace;
reserve X,X1 for set;

theorem
  for f be PartFunc of RNS,CNS, x0 be Point of RNS st x0 in dom f holds
  f is_continuous_on {x0}
proof
  let f be PartFunc of RNS,CNS;
  let x0 be Point of RNS;
  assume
A1: x0 in dom f;
  thus {x0} c= dom f
  by A1,TARSKI:def 1;
  let p be Point of RNS such that
A2: p in {x0};
  thus f|{x0} is_continuous_in p
  proof
    p in dom f by A1,A2,TARSKI:def 1;
    then p in dom f /\ {x0} by A2,XBOOLE_0:def 4;
    hence p in dom (f|{x0}) by RELAT_1:61;
    let s1 be sequence of RNS;
    assume that
A3: rng s1 c= dom(f|{x0}) and
    s1 is convergent and
    lim s1=p;
A4: dom f /\ {x0} c= {x0} by XBOOLE_1:17;
    rng s1 c= dom f /\ {x0} by A3,RELAT_1:61;
    then
A5: rng s1 c= {x0} by A4;
A6: now
      let n;
      dom s1 = NAT by FUNCT_2:def 1;
      then s1.n in rng s1 by FUNCT_1:3;
      hence s1.n = x0 by A5,TARSKI:def 1;
    end;
A7: p=x0 by A2,TARSKI:def 1;
A8: now
      let g be Real such that
A9:   0<g;
      reconsider n=0 as Nat;
      take n;
      let m be Nat such that
      n<=m;
A10:   m in NAT by ORDINAL1:def 12;
      ||. ((f|{x0})/*s1).m - (f|{x0})/.p.|| = ||. (f|{x0})/.(s1.m) - (f|{
      x0})/.x0 .|| by A7,A3,FUNCT_2:109,A10
        .= ||. (f|{x0})/.x0 - (f|{x0})/.x0.|| by A6,A10
        .= ||. 0.CNS .|| by RLVECT_1:15
        .= 0 by CLVECT_1:102;
      hence ||. ((f|{x0})/*s1).m - (f|{x0})/.p .|| < g by A9;
    end;
    hence (f|{x0})/*s1 is convergent by CLVECT_1:def 15;
    hence thesis by A8,CLVECT_1:def 16;
  end;
end;
