reserve E, F, G,S,T,W,Y for RealNormSpace;
reserve f,f1,f2 for PartFunc of S,T;
reserve Z for Subset of S;
reserve i,n for Nat;

theorem
  for X,Y be RealNormSpace,
        V be Subset of [:X,Y:],
        D be Subset of X,
        E be Subset of Y
   st D is open & E is open & V = [:D,E:]
  holds V is open
proof
  let X,Y be RealNormSpace,
        V be Subset of [:X,Y:],
        D be Subset of X,E be Subset of Y;
  assume A1: D is open & E is open & V = [:D,E:];

  for x be Point of X, y be Point of Y
  st [x,y] in V
    ex r1,r2 be Real
    st 0 < r1 & 0 < r2
     & [:Ball(x,r1),Ball(y,r2):] c= V
  proof
    let x be Point of X, y be Point of Y;
    assume [x,y] in V;
    then A2: x in D & y in E by A1,ZFMISC_1:87;
    then consider r be Real such that
    A3: r > 0 & Ball(x,r) c= D by A1,NDIFF_8:20;
    consider r2 be Real such that
    A4: r2 > 0 & Ball(y,r2) c= E by A1,A2,NDIFF_8:20;

    for z be object st z in [:Ball(x,r),Ball(y,r2):] holds z in V
    proof
      let z be object;
      assume z in [:Ball(x,r),Ball(y,r2):];
      then consider qx,qy be object such that
      A5: qx in Ball(x,r) & qy in Ball(y,r2)
        & z = [qx,qy] by ZFMISC_1:def 2;
      reconsider qx as Point of X by A5;
      reconsider qy as Point of Y by A5;
      thus z in V by A1,A3,A4,A5,ZFMISC_1:87;
    end; then
    [:Ball(x,r),Ball(y,r2):] c= V;
    hence thesis by A3,A4;
  end;
  hence thesis by NDIFF10:3;
end;
