reserve i,j,k,l,m,n for Nat,
  D for non empty set,
  f for FinSequence of D;
reserve X for compact Subset of TOP-REAL 2;
reserve r for Real;
reserve f for non trivial FinSequence of TOP-REAL 2;
reserve f for non constant standard special_circular_sequence;

theorem Th61:
  for f being FinSequence of TOP-REAL 2, p being Point of TOP-REAL
2 st f is being_S-Seq & p <> f/.len f & (p`1 = (f/.len f)`1 or p`2 = (f/.len f)
  `2) & LSeg(p,f/.len f) /\ L~f = {f/.len f} holds f^<*p*> is S-Sequence_in_R2
proof
  let f be FinSequence of TOP-REAL 2, p be Point of TOP-REAL 2 such that
A1: f is being_S-Seq and
A2: p <> f/.len f &( p`1 = (f/.len f)`1 or p`2 = (f/.len f)`2) and
A3: LSeg(p,f/.len f) /\ L~f = {f/.len f};
  set g = <*f/.len f,p*>;
A4: g is being_S-Seq by A2,SPPOL_2:43;
AB:  len g = 1+1 by FINSEQ_1:44; then
AA:  2 in dom g by FINSEQ_3:25;
  then
A5: mid(g,2,len g) = <*g.2*> by FINSEQ_6:193,AB
    .= <*g/.2*> by AA,PARTFUN1:def 6
    .= <*p*> by FINSEQ_4:17;
  reconsider f9 = f as S-Sequence_in_R2 by A1;
A6: len f9 in dom f9 by FINSEQ_5:6;
A7: g.1 = f/.len f
    .= f.len f by A6,PARTFUN1:def 6;
  L~f /\ L~g ={ f/.len f } by A3,SPPOL_2:21
    .={f.len f} by A6,PARTFUN1:def 6;
  hence thesis by A1,A7,A4,A5,JORDAN3:38;
end;
