reserve a for set;
reserve L for lower-bounded sup-Semilattice;
reserve x for Element of L;
reserve L for complete LATTICE;
reserve AR for Relation of L;
reserve x, y, z for Element of L;

theorem Th61:
  for R being approximating auxiliary(i) auxiliary(ii) auxiliary(iii)
  Relation of L st R is satisfying_INT holds R is satisfying_SI
proof
  let R be approximating auxiliary(i) auxiliary(ii) auxiliary(iii)
  Relation of L;
  assume
A1: R is satisfying_INT;
  let x, z;
  assume that
A2: [x,z] in R and
A3: x <> z;
  consider y such that
A4: [x,y] in R and
A5: [y,z] in R by A1,A2;
  consider y9 be Element of L such that
A6: x <= y9 and
A7: [y9,z] in R and
A8: x <> y9 by A2,A3,Th49;
A9: x < y9 by A6,A8,ORDERS_2:def 6;
  take Y = y "\/" y9;
A10: x <= y by A4,Def3;
A11: x <= x;
A12: y <= Y by YELLOW_0:22;
  per cases;
  suppose y9 <= y;
    then x < y by A9,ORDERS_2:7;
    hence thesis by A4,A5,A7,A11,A12,Def4,Def5,ORDERS_2:7;
  end;
  suppose not y9 <= y;
    then y <> Y by YELLOW_0:24;
    then y < Y by A12,ORDERS_2:def 6;
    hence thesis by A4,A5,A7,A10,A11,A12,Def4,Def5,ORDERS_2:7;
  end;
end;
