
theorem Th62:
  for C1, C2 being Coherence_Space for A being set st for x,y
being set st x in A & y in A ex f being U-linear Function of C1,C2 st x \/ y =
  LinTrace f ex f being U-linear Function of C1,C2 st union A = LinTrace f
proof
  let C1, C2 be Coherence_Space;
  let A be set such that
A1: for x,y being set st x in A & y in A ex f being U-linear Function of
  C1,C2 st x \/ y = LinTrace f;
  set X = union A;
A2: now
    let a,b be set such that
A3: {a,b} in C1;
    let y1,y2 be object;
    assume [a,y1] in X;
    then consider x1 being set such that
A4: [a,y1] in x1 and
A5: x1 in A by TARSKI:def 4;
    assume [b,y2] in X;
    then consider x2 being set such that
A6: [b,y2] in x2 and
A7: x2 in A by TARSKI:def 4;
A8: x1 c= x1 \/ x2 & x2 c= x1 \/ x2 by XBOOLE_1:7;
    ex f being U-linear Function of C1,C2 st x1 \/ x2 = LinTrace f by A1,A5,A7;
    hence {y1,y2} in C2 by A3,A4,A6,A8,Th53;
  end;
A9: now
    let a,b be set such that
A10: {a,b} in C1;
    let y be object;
    assume [a,y] in X;
    then consider x1 being set such that
A11: [a,y] in x1 and
A12: x1 in A by TARSKI:def 4;
    assume [b,y] in X;
    then consider x2 being set such that
A13: [b,y] in x2 and
A14: x2 in A by TARSKI:def 4;
A15: x1 c= x1 \/ x2 & x2 c= x1 \/ x2 by XBOOLE_1:7;
    ex f being U-linear Function of C1,C2 st x1 \/ x2 = LinTrace f by A1,A12
,A14;
    hence a = b by A10,A11,A13,A15,Th54;
  end;
  X c= [:union C1, union C2:]
  proof
    let x be object;
    assume x in X;
    then consider y being set such that
A16: x in y and
A17: y in A by TARSKI:def 4;
    y \/ y = y;
    then ex f being U-linear Function of C1,C2 st y = LinTrace f by A1,A17;
    hence thesis by A16;
  end;
  hence thesis by A2,A9,Th56;
end;
