reserve h,r,r1,r2,x0,x1,x2,x3,x4,x5,x,a,b,c,k for Real,
  f,f1,f2 for Function of REAL,REAL;

theorem
  for x holds fD(sin(#)sin(#)cos,h).x =(1/2)*(sin((6*x+3*h)/2)*sin(3*h/2
  )-sin((2*x+h)/2)*sin(h/2))
proof
  let x;
  set y=3*x;
  set z=3*h;
  fD(sin(#)sin(#)cos,h).x = (sin(#)sin(#)cos).(x+h) -(sin(#)sin(#)cos).x
  by DIFF_1:3
    .= ((sin(#)sin).(x+h))*(cos.(x+h)) -(sin(#)sin(#)cos).x by VALUED_1:5
    .= (sin.(x+h))*(sin.(x+h))*(cos.(x+h)) -(sin(#)sin(#)cos).x by VALUED_1:5
    .= (sin.(x+h))*(sin.(x+h))*(cos.(x+h)) -((sin(#)sin).x)*(cos.x) by
VALUED_1:5
    .= sin(x+h)*sin(x+h)*cos(x+h) -sin(x)*sin(x)*cos(x) by VALUED_1:5
    .= (1/4)*(-cos((x+h)+(x+h)-(x+h))+cos((x+h)+(x+h)-(x+h)) +cos((x+h)+(x+h
  )-(x+h))-cos((x+h)+(x+h)+(x+h))) -sin(x)*sin(x)*cos(x) by SIN_COS4:34
    .= (1/4)*(cos(x+h)-cos(3*(x+h)))-(1/4)*(-cos(x+x-x) +cos(x+x-x)+cos(x+x-
  x)-cos(x+x+x)) by SIN_COS4:34
    .= (1/4)*(cos(x+h)-cos(x))-(1/4)*(cos(3*(x+h))-cos(3*x))
    .= (1/4)*(-2*(sin((x+h+x)/2)*sin((x+h-x)/2))) -(1/4)*(cos(3*(x+h))-cos(3
  *x)) by SIN_COS4:18
    .= (1/4)*(-2*(sin((2*x+h)/2)*sin(h/2))) -(1/4)*(-2*(sin((y+z+y)/2)*sin((
  y+z-y)/2))) by SIN_COS4:18
    .= (1/2)*(sin((6*x+3*h)/2)*sin(3*h/2)) -(1/2)*((sin((2*x+h)/2)*sin(h/2))
  );
  hence thesis;
end;
