 reserve n,m,i,p for Nat,
         h,k,r,r1,r2,x,x0,x1,x2,x3 for Real;
 reserve f,f1,f2,g for Function of REAL,REAL;

theorem
  x in dom cot & x-h in dom cot implies
  bD(cot(#)cot(#)cos,h).x = cos.x|^3*(sin.x)"|^2 - cos.(x-h)|^3*(sin.(x-h))"|^2
proof
  set f=cot(#)cot(#)cos;
  assume
A1: x in dom cot & x-h in dom cot;
  x in dom f & x-h in dom f
  proof
    set f1=cot(#)cot;
    set f2=cos;
A2: x in dom f1 & x-h in dom f1
    proof
      x in dom cot /\ dom cot & x-h in dom cot /\ dom cot by A1;
      hence thesis by VALUED_1:def 4;
    end;
    x in dom f1 /\ dom f2 & x-h in dom f1 /\ dom f2
                                        by A2,SIN_COS:24,XBOOLE_0:def 4;
    hence thesis by VALUED_1:def 4;
  end;
  then
  bD(f,h).x = (cot(#)cot(#)cos).x - (cot(#)cot(#)cos).(x-h) by DIFF_1:38
    .= (cot(#)cot).x*cos.x - (cot(#)cot(#)cos).(x-h) by VALUED_1:5
    .= (cot(#)cot).x*cos.x - (cot(#)cot).(x-h)*cos.(x-h) by VALUED_1:5
    .= cot.x*cot.x*cos.x - (cot(#)cot).(x-h)*cos.(x-h) by VALUED_1:5
    .= cot.x*cot.x*cos.x - cot.(x-h)*cot.(x-h)*cos.(x-h) by VALUED_1:5
    .= (cos.x*(sin.x)")*cot.x*cos.x
       - cot.(x-h)*cot.(x-h)*cos.(x-h) by A1,RFUNCT_1:def 1
    .= (cos.x*(sin.x)")*(cos.x*(sin.x)")*cos.x
       - cot.(x-h)*cot.(x-h)*cos.(x-h) by A1,RFUNCT_1:def 1
    .= (cos.x*(sin.x)")*(cos.x*(sin.x)")*cos.x
       - (cos.(x-h)*(sin.(x-h))")*cot.(x-h)*cos.(x-h) by A1,RFUNCT_1:def 1
    .= (cos.x*(sin.x)")*(cos.x*(sin.x)")*cos.x
       - (cos.(x-h)*(sin.(x-h))")*(cos.(x-h)*(sin.(x-h))")*cos.(x-h)
                                                      by A1,RFUNCT_1:def 1
    .= (cos.x*cos.x*cos.x)*((sin.x)"*(sin.x)")
       - (cos.(x-h)*cos.(x-h)*cos.(x-h))*((sin.(x-h))"*(sin.(x-h))")
    .= (cos.x|^1*cos.x*cos.x)*((sin.x)"*(sin.x)")
       - (cos.(x-h)*cos.(x-h)*cos.(x-h))*((sin.(x-h))"*(sin.(x-h))")
    .= (cos.x|^(1+1)*cos.x)*((sin.x)"*(sin.x)")
       - (cos.(x-h)*cos.(x-h)*cos.(x-h))*((sin.(x-h))"*(sin.(x-h))")
                                                             by NEWTON:6
    .= cos.x|^(2+1)*((sin.x)"*(sin.x)")
       - (cos.(x-h)*cos.(x-h)*cos.(x-h))*((sin.(x-h))"*(sin.(x-h))")
                                                             by NEWTON:6
    .= cos.x|^3*((sin.x)"|^1*(sin.x)")
       - (cos.(x-h)*cos.(x-h)*cos.(x-h))*((sin.(x-h))"*(sin.(x-h))")
    .= cos.x|^3*(sin.x)"|^(1+1)
       - (cos.(x-h)*cos.(x-h)*cos.(x-h))*((sin.(x-h))"*(sin.(x-h))")
                                                             by NEWTON:6
    .= cos.x|^3*(sin.x)"|^2
       - (cos.(x-h)|^1*cos.(x-h)*cos.(x-h))*((sin.(x-h))"*(sin.(x-h))")
    .= cos.x|^3*(sin.x)"|^2
       - (cos.(x-h)|^(1+1)*cos.(x-h))*((sin.(x-h))"*(sin.(x-h))") by NEWTON:6
    .= cos.x|^3*(sin.x)"|^2
       - cos.(x-h)|^(2+1)*((sin.(x-h))"*(sin.(x-h))") by NEWTON:6
    .= cos.x|^3*(sin.x)"|^2
       - cos.(x-h)|^3*((sin.(x-h))"|^1*(sin.(x-h))")
    .= cos.x|^3*(sin.x)"|^2
       - cos.(x-h)|^3*(sin.(x-h))"|^(1+1) by NEWTON:6
    .= cos.x|^3*(sin.x)"|^2 - cos.(x-h)|^3*(sin.(x-h))"|^2;
  hence thesis;
end;
