reserve D for non empty set,
  i,j,k,l for Nat,
  n for Nat,
  x for set,
  a,b,c,r,r1,r2 for Real,
  p,q for FinSequence of REAL,
  MR,MR1 for Matrix of REAL;

theorem Th62:
  for M being non empty-yielding Conditional_Probability Matrix of
REAL for p being FinSequence of REAL holds p = Entropy_of_Cond_Prob M iff len p
  = len M & for k st k in dom p holds p.k = -Sum ((Infor_FinSeq_of M).k)
proof
  let M be non empty-yielding Conditional_Probability Matrix of REAL;
  let p be FinSequence of REAL;
A1: len Infor_FinSeq_of M = len M by Def8;
  hereby
    assume
A2: p = Entropy_of_Cond_Prob M;
    then
A3: len p = len M by Def11;
    then
A4: dom p = dom M by FINSEQ_3:29;
    now
      let k such that
A5:   k in dom p;
A6:   k in dom (Infor_FinSeq_of M) by A1,A3,A5,FINSEQ_3:29;
      thus p.k = Entropy Line(M,k) by A2,A5,Def11
        .= -Sum Line(Infor_FinSeq_of M,k) by A4,A5,Th53
        .= -Sum ((Infor_FinSeq_of M).k) by A6,MATRIX_0:60;
    end;
    hence len p = len M & for k st k in dom p holds p.k = -Sum ((
    Infor_FinSeq_of M).k) by A2,Def11;
  end;
  assume that
A7: len p = len M and
A8: for k st k in dom p holds p.k = -Sum ((Infor_FinSeq_of M).k);
A9: dom p = dom M by A7,FINSEQ_3:29;
A10: dom Infor_FinSeq_of M = dom M by A1,FINSEQ_3:29;
  now
    let k such that
A11: k in dom p;
    thus p.k = -Sum ((Infor_FinSeq_of M).k) by A8,A11
      .= -Sum Line(Infor_FinSeq_of M,k) by A10,A9,A11,MATRIX_0:60
      .= Entropy Line(M,k) by A9,A11,Th53;
  end;
  hence thesis by A7,Def11;
end;
