
theorem Th62:
  for S being vertex-disjoint GraphUnionSet, G being GraphUnion of S
  for H being Element of S holds H is inducedSubgraph of G, the_Vertices_of H
proof
  let S be vertex-disjoint GraphUnionSet, G be GraphUnion of S;
  let H be Element of S;
  A1: H is Subgraph of G by GLIB_014:21;
  then A2: the_Vertices_of H is non empty Subset of the_Vertices_of G
    by GLIB_000:def 32;
  now
    let x be object;
    hereby
      set v = (the_Source_of H).x, w = (the_Target_of H).x;
      assume x in the_Edges_of H;
      then A3: x Joins v,w,H by GLIB_000:def 13;
      then A4: v in the_Vertices_of H & w in the_Vertices_of H by GLIB_000:13;
      x Joins v,w,G by A1, A3, GLIB_000:72;
      hence x in G.edgesBetween(the_Vertices_of H) by A4, GLIB_000:32;
    end;
    set v = (the_Source_of G).x, w = (the_Target_of G).x;
    assume x in G.edgesBetween(the_Vertices_of H);
    then A5: v in the_Vertices_of H & x in the_Edges_of G by GLIB_000:31;
    then x Joins v,w,G by GLIB_000:def 13;
    then consider H9 being Element of S such that
      A6: x Joins v,w,H9 by GLIBPRE1:117;
    v in the_Vertices_of H9 by A6, GLIB_000:13;
    then H = H9 by A5, Def18, XBOOLE_0:3;
    hence x in the_Edges_of H by A6, GLIB_000:def 13;
  end;
  then the_Edges_of H = G.edgesBetween(the_Vertices_of H) by TARSKI:2;
  hence thesis by A1, A2, GLIB_000:def 37;
end;
