reserve n for Element of NAT;
reserve i for Integer;
reserve G,H,I for Group;
reserve A,B for Subgroup of G;
reserve N for normal Subgroup of G;
reserve a,a1,a2,a3,b,b1 for Element of G;
reserve c,d for Element of H;
reserve f for Function of the carrier of G, the carrier of H;
reserve x,y,y1,y2,z for set;
reserve A1,A2 for Subset of G;
reserve N for normal Subgroup of G;
reserve S,T1,T2 for Element of G./.N;
reserve g,h for Homomorphism of G,H;
reserve h1 for Homomorphism of H,I;

theorem Th62:
  for H being Group, h being Homomorphism of G,H st
  h is bijective holds h" is Homomorphism of H,G
proof
  let H be Group, h be Homomorphism of G,H;
  assume
A1: h is bijective;
  then
A2: h is one-to-one & rng h = the carrier of H by FUNCT_2:def 3;
  then reconsider h1 = h" as Function of H,G by FUNCT_2:25;
  now
    let a,b be Element of H;
    set a1 = h1.a, b1 = h1.b;
    h.a1 = a & h.b1 = b by A2,FUNCT_1:32;
    hence h1.(a * b) = h1.(h.(a1 * b1)) by Def6
      .= h1.a * h1.b by A1,FUNCT_2:26;
  end;
  hence thesis by Def6;
end;
