reserve m,n,i,i2,j for Nat,
  r,r1,r2,s,t for Real,
  x,y,z for object;
reserve p,p1,p2,p3,q,q1,q2,q3,q4 for Point of TOP-REAL n;
reserve u for Point of Euclid n;

theorem Th47:
  for W being Subset of Euclid n,a being Real
   st n>=2 & W=(REAL n)\ {q : (|.q.|) < a } holds W is not bounded
proof
  let W be Subset of Euclid n,a be Real;
  reconsider 1R = 1.REAL n as Point of TOP-REAL n;
  assume
A1: n>=2 & W=(REAL n)\ {q : (|.q.|) < a };
  assume W is bounded;
  then consider r such that
A2: 0<r and
A3: for x,y being Point of Euclid n st x in W & y in W holds dist(x,y)<=
  r;
A4: 0<=|.a.| by COMPLEX1:46;
  then
A5: (r+|.a.|)+0<(r+|.a.|)+(r+|.a.|) by A2,XREAL_1:6;
  n>=1 by A1,XXREAL_0:2;
  then
A6: 1<=sqrt n by SQUARE_1:18,26;
A7: now
    a<=|.a.| & |.a.|<r+|.a.| by A2,ABSVALUE:4,XREAL_1:29;
    then
A8: a<r+|.a.| by XXREAL_0:2;
    assume -((r+|.a.|)*(1.REAL n)) in {q : (|.q.|) < a };
    then
A9: ex q being Point of TOP-REAL n st q=-((r+|.a.|)*(1.REAL n)) & (|.q.|) < a;
    |.r+|.a.|.|>=0 by COMPLEX1:46;
    then
A10: |.r+|.a.|.|*1<=|.r+|.a.|.|*sqrt n by A6,XREAL_1:64;
A11: (r+|.a.|)<=|.r+|.a.|.| by ABSVALUE:4;
    |.-((r+|.a.|)*(1.REAL n)).| = |.((r+|.a.|)*(1.REAL n)).| by TOPRNS_1:26
      .=|.r+|.a.|.|*|.(1.REAL n).| by TOPRNS_1:7
      .=|.r+|.a.|.|*(sqrt n) by EUCLID:73;
    then (r+|.a.|)<= |.-((r+|.a.|)*(1.REAL n)).| by A10,A11,XXREAL_0:2;
    hence contradiction by A9,A8,XXREAL_0:2;
  end;
A12: now
    a<=|.a.| & |.a.|<r+|.a.| by A2,ABSVALUE:4,XREAL_1:29;
    then
A13: a<r+|.a.| by XXREAL_0:2;
    assume (r+|.a.|)*(1.REAL n) in {q : (|.q.|) < a };
    then
A14: ex q being Point of TOP-REAL n st q=(r+|.a.|)*(1.REAL n) & (|.q.|) < a;
    |.r+|.a.|.|>=0 by COMPLEX1:46;
    then
A15: |.r+|.a.|.|*1<=|.r+|.a.|.|*sqrt n by A6,XREAL_1:64;
A16: (r+|.a.|)<=|.r+|.a.|.| by ABSVALUE:4;
    |.(r+|.a.|)*(1.REAL n).|=|.r+|.a.|.|*|.(1.REAL n).| by TOPRNS_1:7
      .=|.r+|.a.|.|*(sqrt n) by EUCLID:73;
    then (r+|.a.|)<= |.(r+|.a.|)*(1.REAL n).| by A15,A16,XXREAL_0:2;
    hence contradiction by A14,A13,XXREAL_0:2;
  end;
  reconsider z2=-((r+|.a.|)*(1.REAL n)) as Point of Euclid n by EUCLID:22;
  reconsider z1=(r+|.a.|)*(1.REAL n) as Point of Euclid n by EUCLID:22;
A17: (r+|.a.|)+(r+|.a.|)<=|.(r+|.a.|)+(r+|.a.|).| by ABSVALUE:4;
  |.((r+|.a.|)+(r+|.a.|)).|>=0 by COMPLEX1:46;
  then
A18: |.(r+|.a.|)+(r+|.a.|).|*1<=|.(r+|.a.|)+(r+|.a.|).|*sqrt n by A6,XREAL_1:64
;
  dist(z1,z2)=|.(r+|.a.|)*(1.REAL n)--((r+|.a.|)*(1.REAL n)).| by JGRAPH_1:28
    .=|.(r+|.a.|)*1R + --((r+|.a.|)*1R).|
    .=|.(r+|.a.|)*1R+((r+|.a.|)*1R).|
    .=|.((r+|.a.|)+(r+|.a.|))*1R .| by RLVECT_1:def 6
    .=|.((r+|.a.|)+(r+|.a.|))*(1.REAL n).|
    .=|.((r+|.a.|)+(r+|.a.|)).|*|.(1.REAL n).| by TOPRNS_1:7
    .=|.((r+|.a.|)+(r+|.a.|)).|*(sqrt n) by EUCLID:73;
  then (r+|.a.|)+(r+|.a.|)<= dist(z1,z2) by A18,A17,XXREAL_0:2;
  then
A19: (r+|.a.|)<dist(z1,z2) by A5,XXREAL_0:2;
  r+0<=r+|.a.| by A4,XREAL_1:6;
  then
A20: r<dist(z1,z2) by A19,XXREAL_0:2;
  -((r+|.a.|)*(1.REAL n)) in the carrier of TOP-REAL n;
  then -((r+|.a.|)*(1.REAL n)) in REAL n by EUCLID:22;
  then
A21: -((r+|.a.|)*(1.REAL n)) in W by A1,A7,XBOOLE_0:def 5;
  (r+|.a.|)*(1.REAL n) in the carrier of TOP-REAL n;
  then (r+|.a.|)*(1.REAL n) in REAL n by EUCLID:22;
  then (r+|.a.|)*(1.REAL n) in W by A1,A12,XBOOLE_0:def 5;
  hence contradiction by A3,A21,A20;
end;
