
theorem
for x be Element of REAL, I,J,K be non empty closed_interval Subset of REAL,
  f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
  g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
  P1Gz be PartFunc of REAL,REAL st
  x in I & [:[:I,J:],K:] = dom f & f is_continuous_on [:[:I,J:],K:] & f = g
& P1Gz = ProjPMap1(Integral2(L-Meas,R_EAL g),x)|J holds
   ProjPMap1(Integral2(L-Meas,R_EAL g),x)|J is_integrable_on L-Meas
 & integral(P1Gz,J) =Integral(L-Meas,ProjPMap1(Integral2(L-Meas,R_EAL g),x)|J)
 & integral(P1Gz,J) = Integral(L-Meas,ProjPMap1(Integral2(L-Meas,R_EAL g),x))
 & integral(P1Gz,J) = (Integral2(L-Meas,Integral2(L-Meas,R_EAL g))).x
proof
    let x be Element of REAL;
    let I,J,K be non empty closed_interval Subset of REAL,
    f be PartFunc of [:[:RNS_Real,RNS_Real:],RNS_Real:],RNS_Real,
    g be PartFunc of [:[:REAL,REAL:],REAL:],REAL,
    P1Gz be PartFunc of REAL,REAL;
    assume that
A1: x in I and
A2: [:[:I,J:],K:] = dom f and
A3: f is_continuous_on [:[:I,J:],K:] and
A4: f = g and
A5: P1Gz = ProjPMap1(Integral2(L-Meas,R_EAL g),x)|J;

    set Gz = Integral2(L-Meas,R_EAL g);

A6: J is Element of L-Field by MEASUR10:5,MEASUR12:75;

A7: ProjPMap1(Gz,x) is_integrable_on L-Meas by A2,A3,A4,Th46;
    hence ProjPMap1(Integral2(L-Meas,R_EAL g),x)|J is_integrable_on L-Meas
      by A6,MESFUNC5:97;

A8: dom(Integral2(L-Meas,R_EAL g)) = [:REAL,REAL:] by FUNCT_2:def 1;
    [#]REAL = REAL by SUBSET_1:def 3; then
    dom(ProjPMap1(Integral2(L-Meas,R_EAL g),x)) = REAL by A8,MESFUN16:25; then
A9: dom P1Gz = J by A5;
    P1Gz||J is bounded & P1Gz is_integrable_on J by A1,A2,A3,A4,A5,Th59; then
    P1Gz|J is_integrable_on L-Meas
  & Integral(L-Meas,P1Gz|J) = integral(P1Gz||J) by A6,A9,MESFUN14:49;
    hence
A10: integral(P1Gz,J)
      = Integral(L-Meas,ProjPMap1(Integral2(L-Meas,R_EAL g),x)|J)
      by A5,MESFUNC5:def 7;

    REAL in L-Field by PROB_1:5; then
    reconsider NJ = REAL \ J as Element of L-Field by A6,PROB_1:6;
    set PGz10 = ProjPMap1(Gz,x)|J;
    set PGz11 = ProjPMap1(Gz,x)|NJ;

A11:Integral(L-Meas,PGz11) = 0 by A2,A4,Th54;

    J \/ NJ = REAL by XBOOLE_1:45; then
    ProjPMap1(Gz,x)|(J \/ NJ) = ProjPMap1(Gz,x); then
    Integral(L-Meas,ProjPMap1(Gz,x))
      = Integral(L-Meas,PGz10) + Integral(L-Meas,PGz11)
       by A6,A7,XBOOLE_1:85,MESFUNC5:98;
    hence integral(P1Gz,J) = Integral(L-Meas,ProjPMap1(Gz,x))
      by A10,A11,XXREAL_3:4;
    hence integral(P1Gz,J) = (Integral2(L-Meas,Integral2(L-Meas,R_EAL g))).x
      by MESFUN12:def 8;
end;
