
theorem Th62:
  for L,K be ExtREAL_sequence,c be Real st 0 <= c & L is
  without-infty & (for n be Nat holds K.n = c * L.n ) holds sup rng K =
   c * sup rng L & K is without-infty
proof
  let L,K be ExtREAL_sequence;
  let c be Real;
  assume that
A1: 0 <= c and
A2: L is without-infty and
A3: for n be Nat holds K.n = c * L.n;
  now
    per cases by A2,Lm8;
    suppose
A4:   sup rng L in REAL;
A5:   for y being UpperBound of rng K holds c * sup rng L <= y
      proof
        let y be UpperBound of rng K;
        reconsider y as R_eal by XXREAL_0:def 1;
A6:     dom L = NAT by FUNCT_2:def 1;
A7:     dom K = NAT by FUNCT_2:def 1;
        per cases;
        suppose
A8:      c = 0;
A9:      K.1 <= y by A7,FUNCT_1:3,XXREAL_2:def 1;
          K.1 = c * L.1 by A3;
          hence thesis by A8,A9;
        end;
        suppose
A10:      c <> 0;
          now
            let x be ExtReal;
            assume x in rng L;
            then consider n be object such that
A11:        n in dom L and
A12:        x = L.n by FUNCT_1:def 3;
            reconsider n as Element of NAT by A11;
A13:        K.n in rng K by A7,FUNCT_1:3;
            K.n = c * L.n by A3;
            then c * L.n / c <= y/ c by A1,A10,A13,
XXREAL_2:def 1,XXREAL_3:79;
            hence x <= y / c by A10,A12,XXREAL_3:88;
          end;
          then y/c is UpperBound of rng L by XXREAL_2:def 1;
          then
A14:      sup rng L <= y/c by XXREAL_2:def 3;
A15:      now
            assume
A16:        y = -infty;
            K.1 in rng K by A7,FUNCT_1:3;
            then K.1 = -infty by A16,XXREAL_0:6,XXREAL_2:def 1;
            then
A17:        c * L.1 = -infty by A3;
            L.1 <= sup rng L by A6,FUNCT_1:3,XXREAL_2:4;
            then
A18:        L.1 < +infty by A4,XXREAL_0:2,9;
            -infty < L.1 by A2;
            hence contradiction by A17,A18,XXREAL_3:70;
          end;
          per cases by A15,XXREAL_0:14;
          suppose
            y = +infty;
            hence thesis by XXREAL_0:4;
          end;
          suppose
            y in REAL;
            then reconsider ry = y as Real;
            reconsider sl = sup rng L as Real by A4;
            y/c = ry/c;
            then sl*c <= ry by A1,A10,A14,XREAL_1:83;
            hence thesis;
          end;
        end;
      end;
      now
        let x be ExtReal;
A19:    sup rng L is UpperBound of rng L by XXREAL_2:def 3;
        assume x in rng K;
        then consider m be object such that
A20:    m in dom K and
A21:    x = K.m by FUNCT_1:def 3;
        reconsider m as Element of NAT by A20;
        dom L = NAT by FUNCT_2:def 1;
        then
A22:    L.m <= sup rng L by A19,FUNCT_1:3,XXREAL_2:def 1;
        x = c * L.m by A3,A21;
        hence x <= c*sup rng L by A1,A22,XXREAL_3:71;
      end;
      then c * sup rng L is UpperBound of rng K by XXREAL_2:def 1;
      hence sup rng K = c * sup rng L by A5,XXREAL_2:def 3;
    end;
    suppose
A23:  sup rng L = +infty;
      per cases;
      suppose
A24:    c = 0;
A25:    now
          let n be Nat;
          K.n = c * L.n by A3;
          hence K.n = 0 by A24;
        end;
        then lim K = sup rng K by Th60;
        hence sup rng K = c * sup rng L by A24,A25,Th60;
      end;
      suppose
A26:    c <> 0;
        now
          let n be object;
          -infty < L.n by A2;
          then
A27:      -infty* c < c * L.n by A1,A26,XXREAL_3:72;
          per cases;
          suppose
            n in dom K;
            then reconsider n1=n as Element of NAT;
            -infty* c = -infty by A1,A26,XXREAL_3:def 5;
            then -infty < K.n1 by A3,A27;
            hence -infty < K.n;
          end;
          suppose
            not n in dom K;
            hence -infty < K.n by FUNCT_1:def 2;
          end;
        end;
        then
A28:    K is without-infty;
A29:    now
          let k be Real;
          reconsider k1 = k as Real;
A30:      (k/c)* c = k1/c * c
            .= k1/(c/c) by XCMPLX_1:82
            .= k by A26,XCMPLX_1:51;
          assume 0 < k;
          then consider n be Nat such that
A31:      (k/c) < L.n by A1,A2,A23,A26,Th59;
          (k/c) * c < c * L.n by A1,A26,A31,XXREAL_3:72;
          then k < K.n by A3,A30;
          hence ex n be Nat st not K.n <= k;
        end;
         c * sup rng L = +infty by A1,A23,A26,XXREAL_3:def 5;
        hence sup rng K = c * sup rng L by A28,A29,Th59;
      end;
    end;
  end;
  hence sup rng K = c * sup rng L;
  now
    let n be object;
A32: L.n = +infty implies c * L.n <> -infty by A1;
    -infty < L.n by A2;
    then
A33: -infty <> c * L.n by A32,XXREAL_3:70;
    per cases;
    suppose
      n in dom K;
      then reconsider n1=n as Element of NAT;
      K.n1 <> -infty by A3,A33;
      hence -infty < K.n by XXREAL_0:6;
    end;
    suppose
      not n in dom K;
      hence -infty < K.n by FUNCT_1:def 2;
    end;
  end;
  hence thesis;
end;
