reserve E, F, G,S,T,W,Y for RealNormSpace;
reserve f,f1,f2 for PartFunc of S,T;
reserve Z for Subset of S;
reserve i,n for Nat;

theorem Th63:
  for E, F,G be RealNormSpace,
      x be Point of R_NormSpace_of_BoundedLinearOperators(E,F),
      L be Point of R_NormSpace_of_BoundedLinearOperators(
         R_NormSpace_of_BoundedLinearOperators(F,E),
         R_NormSpace_of_BoundedLinearOperators(E,E))
   st x is invertible
    & for y be Point of R_NormSpace_of_BoundedLinearOperators(F,E)
      holds L.y = y*x
  holds L is invertible
proof
  let E, F,G be RealNormSpace,
      x be Point of R_NormSpace_of_BoundedLinearOperators(E,F),
      L be Point of R_NormSpace_of_BoundedLinearOperators(
          R_NormSpace_of_BoundedLinearOperators(F,E),
          R_NormSpace_of_BoundedLinearOperators(E,E));
  assume that
  A1: x is invertible and
  A2: for y be Point of R_NormSpace_of_BoundedLinearOperators(F,E)
      holds L.y = y*x;

  set EF = R_NormSpace_of_BoundedLinearOperators(E,F);
  set FE = R_NormSpace_of_BoundedLinearOperators(F,E);
  set EE = R_NormSpace_of_BoundedLinearOperators(E,E);
  set FEEE = R_NormSpace_of_BoundedLinearOperators(
                R_NormSpace_of_BoundedLinearOperators(F,E),
                R_NormSpace_of_BoundedLinearOperators(E,E));

  reconsider L1 = L as Lipschitzian LinearOperator of FE,EE by LOPBAN_1:def 9;
  reconsider x0 = x as Lipschitzian LinearOperator of E,F by LOPBAN_1:def 9;

  A3: modetrans(x,E,F) = x0 by LOPBAN_1:def 11;
  A4: x is one-to-one & rng x =[#]F
    & x" is Point of R_NormSpace_of_BoundedLinearOperators(F,E)
      by A1,LOPBAN13:def 1;
  reconsider dx = x" as Point of
    R_NormSpace_of_BoundedLinearOperators(F,E) by A1,LOPBAN13:def 1;

  reconsider dx0 = dx as Lipschitzian LinearOperator of F,E by LOPBAN_1:def 9;
  A5: modetrans(dx,F,E) = dx0 by LOPBAN_1:def 11;
  A6: for x1, x2 be object st x1 in [#]FE & x2 in [#]FE & L1.x1 = L1.x2
      holds x1 = x2
  proof
    let z1, z2 be object;
    assume A7: z1 in [#]FE & z2 in [#]FE & L1.z1 = L1.z2;
    reconsider z10 = z1, z20 = z2 as Point of FE by A7;
    A8: L1.z20 = z20*x by A2;

    reconsider z100 = z10 as Lipschitzian LinearOperator of F,E
      by LOPBAN_1:def 9;
    reconsider z200 = z20 as Lipschitzian LinearOperator of F,E
      by LOPBAN_1:def 9;

    A9:  modetrans(z10,F,E) = z100 by LOPBAN_1:def 11;
    A10: modetrans(z20,F,E) = z200 by LOPBAN_1:def 11;

    A11: z100 * x0
     = z10 * x by A9,LOPBAN_1:def 11
    .= z20 * x by A2,A7,A8
    .= z200 * x0 by A10,LOPBAN_1:def 11;

    z100
     = z100 * (id [#]F) by FUNCT_2:17
    .= z100 * (x0 * x0") by A4,FUNCT_2:29
    .= (z100 * x0) * x0" by RELAT_1:36
    .= z200 * (x0 * x0") by A11,RELAT_1:36
    .= z200 * (id [#]F) by A4,FUNCT_2:29
    .= z200 by FUNCT_2:17;
    hence z1 = z2;
  end;
  then A12: L is one-to-one by FUNCT_2:19;

  for y be object st y in [#]EE
  holds ex z be object st z in [#]FE & y = L1.z
  proof
    let y be object;
    assume y in [#]EE;
    then reconsider y0 = y as Point of EE;
    reconsider y00 = y0 as Lipschitzian LinearOperator of E,E
      by LOPBAN_1:def 9;
    reconsider ddx = dx*x as Lipschitzian LinearOperator of E,E
      by LOPBAN_1:def 9;
    A13: modetrans(dx*x,E,E) = ddx by LOPBAN_1:def 11;
    A14: ddx
     = dx0 * x0 by A3,LOPBAN_1:def 11
    .= id E by A4,LOPBAN13:11;

    take z = y0 * dx;
    thus z in [#]FE;
    L1.z
     = y0 * dx * x by A2
    .= y0 * (dx * x) by LOPBAN13:10
    .= y00 * (id E) by A13,A14,LOPBAN_1:def 11
    .= y by FUNCT_2:17;
    hence thesis;
  end;
  then A15: rng L1 = [#]EE by FUNCT_2:10;
  then A16: L1 is bijective by A6,FUNCT_2:19,def 3;

  defpred P2[object, object] means
  ex y be Point of EE
  st y = $1 & $2 = y*dx;

  A17: for y be object st y in the carrier of EE
       holds ex z be object st z in the carrier of FE & P2[y,z]
  proof
    let y be object;
    assume y in the carrier of EE;
    then reconsider V1 = y as Point of EE;
    take z = V1 * dx;
    thus thesis;
  end;

  consider R be Function of the carrier of EE, the carrier of FE
  such that
  A18: for y be object st y in the carrier of EE
       holds P2[y, R.y] from FUNCT_2:sch 1(A17);
  A19: for y be Point of EE holds R.y = y * dx
  proof
    let y be Point of EE;
    ex V be Point of EE
    st V = y & R.y = V * dx by A18;
    hence thesis;
  end;

  for y be Element of FE holds (R * L1).y = y
  proof
    let y0 be Element of FE;

    reconsider y00 = y0 as Lipschitzian LinearOperator of F,E
      by LOPBAN_1:def 9;
    A20: modetrans(y0,F,E) = y00 by LOPBAN_1:def 11;
    reconsider xdx = x * dx as Lipschitzian LinearOperator of F,F
      by LOPBAN_1:def 9;
    A21: xdx
     = x0 * dx0 by A5,LOPBAN_1:def 11
    .= id F by A4,LOPBAN13:11;

    thus (R * L1).y0
     = R.(L1.y0) by FUNCT_2:15
    .= R.(y0 * x) by A2
    .= (y0 * x) * dx by A19
    .= y0 * (x * dx) by LOPBAN13:10
    .= y00 * (id F) by A20,A21,LOPBAN_1:def 11
    .= y0 by FUNCT_2:17;
  end;
  then A22: R * L1 = id [#]FE;
  then R = L" by A12,A15,FUNCT_2:30;
  then reconsider R as LinearOperator of EE,FE by A16,LOPBAN_7:1;

  set K = ||.dx.||;

  for y be VECTOR of EE holds ||.R.y.|| <= K * ||.y.||
  proof
    let y be VECTOR of EE;
    reconsider y0 = y as Lipschitzian LinearOperator of E,E by LOPBAN_1:def 9;
    A23: modetrans(y,E,E) = y0 by LOPBAN_1:def 11;
    ||.y * dx.|| <= ||.y.|| * ||.dx.|| by A5,A23,LOPBAN_2:2;
    hence thesis by A19;
  end;
  then reconsider R as Lipschitzian LinearOperator of EE,FE
    by LOPBAN_1:def 8,NORMSP_1:4;

  R = L" by A12,A15,A22,FUNCT_2:30;
  then L" is Point of R_NormSpace_of_BoundedLinearOperators(EE,FE)
    by LOPBAN_1:def 9;
  hence thesis by A12,A15,LOPBAN13:def 1;
end;
