reserve i,j,k,n,m for Nat,
  x,y,z,y1,y2 for object, X,Y,D for set,
  p,q for XFinSequence;
reserve k1,k2 for Nat;
reserve D for non empty set,
  F,G for XFinSequence of D,
  b for BinOp of D,
  d,d1,d2 for Element of D;
reserve F for XFinSequence,
        rF,rF1,rF2 for real-valued XFinSequence,
        r for Real,
        cF,cF1,cF2 for complex-valued XFinSequence,
        c,c1,c2 for Complex;

theorem Th62:
  c(#)cF|n = (c(#)cF)|n
proof
  set ccF=c(#)cF;
  set cFn = cF|n;
A1:len ccF = len cF & len (c(#)cFn) = len cFn by VALUED_1:def 5;
  per cases;
    suppose A2:n <= len cF;
        then A3:len(cFn) = n & len (ccF|n)=n by A1,AFINSQ_1:54;
        now let i;
          assume i < len (c(#)cFn);
          then A4: i in dom (c(#)cFn) by AFINSQ_1:86;
          thus (c(#)cFn).i = c* (cFn.i) by VALUED_1:6
                           .= c* (cF.i) by A4,A2,AFINSQ_1:53
                           .=ccF.i by VALUED_1:6
             .=(ccF|n).i by A4,A1,A2,AFINSQ_1:53;
        end;
        hence thesis by A1,A3,AFINSQ_1:9;
    end;
    suppose n > len cF;
       then cF|n= cF & ccF|n=ccF by A1,AFINSQ_1:52;
       hence thesis;
    end;
end;
