reserve W,X,Y,Z for set,
  f,g for Function,
  a,x,y,z for set;
reserve u,v for Element of Tarski-Class(X),
  A,B,C for Ordinal,
  L for Sequence;
reserve n for Element of omega;

theorem Th63:
  the_rank_of bool X = succ the_rank_of X
proof
A1: X c= Rank the_rank_of X by Def9;
A2: bool X c= Rank succ the_rank_of X
  proof
    let x be object;
            reconsider xx=x as set by TARSKI:1;
    assume x in bool X;
then A3: xx c= Rank the_rank_of X by A1;
 bool Rank the_rank_of X = Rank succ the_rank_of X by Lm2;
    hence thesis by A3;
  end;
 for A st bool X c= Rank A holds succ the_rank_of X c= A
  proof
    let A such that
A4: bool X c= Rank A;
    defpred P[Ordinal] means X in Rank $1;
A5: X in bool X by ZFMISC_1:def 1;
then A6: ex A st P[A] by A4;
    consider B such that
A7: P[B] & for C st P[C] holds B c= C from ORDINAL1:sch 1(A6);
 now
      assume for C holds B <> succ C;
then   B is limit_ordinal by ORDINAL1:29;
then   ex C st C in B & X in Rank C by A7,Lm2,Th31;
      hence contradiction by A7,ORDINAL1:5;
    end;
    then consider C such that
A8: B = succ C;
 X c= Rank C by A7,A8,Th32;
then  the_rank_of X c= C by Def9;
then A9: the_rank_of X in B by A8,ORDINAL1:22;
 B c= A by A4,A5,A7;
    hence thesis by A9,ORDINAL1:21;
  end;
  hence thesis by A2,Def9;
end;
