 reserve n,m,i,p for Nat,
         h,k,r,r1,r2,x,x0,x1,x2,x3 for Real;
 reserve f,f1,f2,g for Function of REAL,REAL;

theorem
  x+h/2 in dom cot & x-h/2 in dom cot implies
  cD(cot(#)cot(#)cos,h).x = cos.(x+h/2)|^3*(sin.(x+h/2))"|^2
  - cos.(x-h/2)|^3*(sin.(x-h/2))"|^2
proof
  set f=cot(#)cot(#)cos;
  assume
A1: x+h/2 in dom cot & x-h/2 in dom cot;
  x+h/2 in dom f & x-h/2 in dom f
  proof
    set f1=cot(#)cot;
    set f2=cos;
A2: x+h/2 in dom f1 & x-h/2 in dom f1
    proof
      x+h/2 in dom cot /\ dom cot & x-h/2 in dom cot /\ dom cot by A1;
      hence thesis by VALUED_1:def 4;
    end;
    x+h/2 in dom f1 /\ dom f2 & x-h/2 in dom f1 /\ dom f2
                                        by A2,SIN_COS:24,XBOOLE_0:def 4;
    hence thesis by VALUED_1:def 4;
  end;
  then
  cD(f,h).x = (cot(#)cot(#)cos).(x+h/2) - (cot(#)cot(#)cos).(x-h/2)
    by DIFF_1:39
    .= (cot(#)cot).(x+h/2)*cos.(x+h/2) - (cot(#)cot(#)cos).(x-h/2)
                                                           by VALUED_1:5
    .= (cot(#)cot).(x+h/2)*cos.(x+h/2) - (cot(#)cot).(x-h/2)*cos.(x-h/2)
                                                           by VALUED_1:5
    .= cot.(x+h/2)*cot.(x+h/2)*cos.(x+h/2) - (cot(#)cot).(x-h/2)*cos.(x-h/2)
                                                             by VALUED_1:5
    .= cot.(x+h/2)*cot.(x+h/2)*cos.(x+h/2)
       - cot.(x-h/2)*cot.(x-h/2)*cos.(x-h/2) by VALUED_1:5
    .= (cos.(x+h/2)*(sin.(x+h/2))")*cot.(x+h/2)*cos.(x+h/2)
       - cot.(x-h/2)*cot.(x-h/2)*cos.(x-h/2) by A1,RFUNCT_1:def 1
    .= (cos.(x+h/2)*(sin.(x+h/2))")*(cos.(x+h/2)*(sin.(x+h/2))")*cos.(x+h/2)
       - cot.(x-h/2)*cot.(x-h/2)*cos.(x-h/2) by A1,RFUNCT_1:def 1
    .= (cos.(x+h/2)*(sin.(x+h/2))")*(cos.(x+h/2)*(sin.(x+h/2))")*cos.(x+h/2)
       - (cos.(x-h/2)*(sin.(x-h/2))")*cot.(x-h/2)*cos.(x-h/2)
                                                        by A1,RFUNCT_1:def 1
    .= (cos.(x+h/2)*(sin.(x+h/2))")*(cos.(x+h/2)*(sin.(x+h/2))")*cos.(x+h/2)
       - (cos.(x-h/2)*(sin.(x-h/2))")*(cos.(x-h/2)*(sin.(x-h/2))")*cos.(x-h/2)
                                                      by A1,RFUNCT_1:def 1
    .= (cos.(x+h/2)*cos.(x+h/2)*cos.(x+h/2))*((sin.(x+h/2))"*(sin.(x+h/2))")
       - (cos.(x-h/2)*cos.(x-h/2)*cos.(x-h/2))*((sin.(x-h/2))"*(sin.(x-h/2))")
    .= (cos.(x+h/2)|^1*cos.(x+h/2)*cos.(x+h/2))*((sin.(x+h/2))"*(sin.(x+h/2))")
       - (cos.(x-h/2)*cos.(x-h/2)*cos.(x-h/2))*((sin.(x-h/2))"*(sin.(x-h/2))")
    .= (cos.(x+h/2)|^(1+1)*cos.(x+h/2))*((sin.(x+h/2))"*(sin.(x+h/2))")
       - (cos.(x-h/2)*cos.(x-h/2)*cos.(x-h/2))*((sin.(x-h/2))"*(sin.(x-h/2))")
                                                             by NEWTON:6
    .= cos.(x+h/2)|^(2+1)*((sin.(x+h/2))"*(sin.(x+h/2))")
       - (cos.(x-h/2)*cos.(x-h/2)*cos.(x-h/2))*((sin.(x-h/2))"*(sin.(x-h/2))")
                                                             by NEWTON:6
    .= cos.(x+h/2)|^3*((sin.(x+h/2))"|^1*(sin.(x+h/2))")
       - (cos.(x-h/2)*cos.(x-h/2)*cos.(x-h/2))*((sin.(x-h/2))"*(sin.(x-h/2))")
    .= cos.(x+h/2)|^3*(sin.(x+h/2))"|^(1+1)
       - (cos.(x-h/2)*cos.(x-h/2)*cos.(x-h/2))*((sin.(x-h/2))"*(sin.(x-h/2))")
                                                             by NEWTON:6
    .= cos.(x+h/2)|^3*(sin.(x+h/2))"|^2
       - (cos.(x-h/2)|^1*cos.(x-h/2)*cos.(x-h/2))
       *((sin.(x-h/2))"*(sin.(x-h/2))")
    .= cos.(x+h/2)|^3*(sin.(x+h/2))"|^2
       - (cos.(x-h/2)|^(1+1)*cos.(x-h/2))*((sin.(x-h/2))"*(sin.(x-h/2))")
                                                                by NEWTON:6
    .= cos.(x+h/2)|^3*(sin.(x+h/2))"|^2
       - cos.(x-h/2)|^(2+1)*((sin.(x-h/2))"*(sin.(x-h/2))") by NEWTON:6
    .= cos.(x+h/2)|^3*(sin.(x+h/2))"|^2
       - cos.(x-h/2)|^3*((sin.(x-h/2))"|^1*(sin.(x-h/2))")
    .= cos.(x+h/2)|^3*(sin.(x+h/2))"|^2
       - cos.(x-h/2)|^3*(sin.(x-h/2))"|^(1+1) by NEWTON:6
    .= cos.(x+h/2)|^3*(sin.(x+h/2))"|^2 - cos.(x-h/2)|^3*(sin.(x-h/2))"|^2;
  hence thesis;
end;
