
theorem Th63:
  for G1, G2 being _Graph, H being Subgraph of G2
  for F being PGraphMapping of G1, G2
  holds (F is empty implies H |` F is empty) &
    (F is one-to-one implies H |` F is one-to-one) &
    (F is onto implies H |` F is onto) &
    (F is non total implies H |` F is non total) &
    (F is directed implies H |` F is directed) &
    (F is semi-continuous implies H |` F is semi-continuous) &
    (F is continuous implies H |` F is continuous) &
    (F is semi-Dcontinuous implies H |` F is semi-Dcontinuous) &
    (F is Dcontinuous implies H |` F is Dcontinuous)
proof
  let G1, G2 be _Graph, H be Subgraph of G2;
  let F be PGraphMapping of G1, G2;
  reconsider f = (the_Vertices_of H) |` F_V
    as PartFunc of the_Vertices_of G1, the_Vertices_of H by PARTFUN1:12;
  reconsider g = (the_Edges_of H) |` F_E
    as PartFunc of the_Edges_of G1, the_Edges_of H by PARTFUN1:12;
  hereby
    assume F is empty;
    then F_V is empty;
    hence H |` F is empty by RELAT_1:86, XBOOLE_1:3;
  end;
  thus F is one-to-one implies H |` F is one-to-one by FUNCT_1:58;
  thus F is onto implies H |` F is onto
  proof
    assume A1: F is onto;
    thus rng (H|`F)_V =rng F_V /\ the_Vertices_of H by RELAT_1:88
      .= the_Vertices_of H by A1, XBOOLE_1:28;
    thus rng (H|`F)_E = rng F_E /\ the_Edges_of H by RELAT_1:88
      .= the_Edges_of H by A1, XBOOLE_1:28;
  end;
  now
    assume A2: H |` F is total;
    dom (H|`F)_V c= dom F_V by RELAT_1:186;
    hence dom F_V = the_Vertices_of G1 by A2, XBOOLE_0:def 10;
    dom (H|`F)_E c= dom F_E by RELAT_1:186;
    hence dom F_E = the_Edges_of G1 by A2, XBOOLE_0:def 10;
  end;
  hence F is non total implies H |` F is non total;
  thus F is directed implies H |` F is directed
  proof
    assume A3: F is directed;
    let e,v,w be object;
    assume A4: e in dom (H|`F)_E & v in dom (H|`F)_V & w in dom (H|`F)_V;
    then A5: e in dom F_E & F_E.e in the_Edges_of H &
      v in dom F_V & F_V.v in the_Vertices_of H &
      w in dom F_V & F_V.w in the_Vertices_of H by FUNCT_1:54;
    then e DJoins v,w,G1 implies F_E.e DJoins F_V.v,F_V.w,G2 by A3;
    then A6: e DJoins v,w,G1 implies F_E.e DJoins F_V.v,F_V.w,H
      by A5, GLIB_000:73;
    (H|`F)_E.e = F_E.e & (H|`F)_V.v = F_V.v & (H|`F)_V.w = F_V.w
      by A4, FUNCT_1:53;
    hence e DJoins v,w,G1 implies
      (H|`F)_E.e DJoins (H|`F)_V.v,(H|`F)_V.w,H by A6;
  end;
  thus F is semi-continuous implies H |` F is semi-continuous
  proof
    assume A7: F is semi-continuous;
    reconsider f = (the_Vertices_of H) |` F_V
      as PartFunc of the_Vertices_of G1, the_Vertices_of H by PARTFUN1:12;
    reconsider g = (the_Edges_of H) |` F_E
      as PartFunc of the_Edges_of G1, the_Edges_of H by PARTFUN1:12;
    let e,v,w be object;
    assume A8: e in dom (H |` F)_E & v in dom (H |` F)_V & w in dom (H |` F)_V;
    then e in dom F_E & F_E.e in the_Edges_of H &
      v in dom F_V & F_V.v in the_Vertices_of H &
      w in dom F_V & F_V.w in the_Vertices_of H by FUNCT_1:54;
    then F_E.e Joins F_V.v,F_V.w,G2 implies e Joins v,w,G1 by A7;
    then A9: F_E.e Joins F_V.v,F_V.w,H implies e Joins v,w,G1 by GLIB_000:72;
    g.e = F_E.e & f.v = F_V.v & f.w = F_V.w by A8, FUNCT_1:53;
    hence thesis by A9;
  end;
  thus F is continuous implies H |` F is continuous
  proof
    assume A10: F is continuous;
    now
      let e9,v,w be object;
      set f = (the_Vertices_of H) |` (F_V);
      assume A11: v in dom (H |` F)_V & w in dom (H |` F)_V &
        e9 Joins (H |` F)_V.v,(H |` F)_V.w,H;
      then A12: v in dom f & w in dom f & e9 Joins f.v,f.w,H;
      then A13: f.v = F_V.v & f.w = F_V.w by FUNCT_1:55;
      A14: v in dom F_V & F_V.v in the_Vertices_of H &
        w in dom F_V & F_V.w in the_Vertices_of H &
        v is set & w is set by A11, FUNCT_1:54;
      e9 Joins F_V.v,F_V.w,G2 by A12, A13, GLIB_000:72;
      then consider e being object such that
        A15: e Joins v,w,G1 & e in dom F_E & F_E.e = e9 by A10, A14;
      take e;
      thus e Joins v,w,G1 by A15;
      e9 in the_Edges_of H by A11, GLIB_000:def 13;
      then e in dom ((the_Edges_of H) |` (F_E)) by A15, FUNCT_1:54;
      hence e in dom (H |` F)_E & (H |` F)_E.e = e9 by A15, FUNCT_1:55;
    end;
    hence thesis;
  end;
  thus F is semi-Dcontinuous implies H |` F is semi-Dcontinuous
  proof
    assume A16: F is semi-Dcontinuous;
    let e,v,w be object;
    assume A17: e in dom (H|`F)_E & v in dom (H|`F)_V & w in dom (H|`F)_V;
    then e in dom F_E & F_E.e in the_Edges_of H &
      v in dom F_V & F_V.v in the_Vertices_of H &
      w in dom F_V & F_V.w in the_Vertices_of H by FUNCT_1:54;
    then A18: F_E.e DJoins F_V.v,F_V.w,H implies e DJoins v,w,G1
      by A16, GLIB_000:72;
    (H|`F)_E.e = F_E.e & (H|`F)_V.v = F_V.v & (H|`F)_V.w = F_V.w
      by A17, FUNCT_1:53;
    hence (H|`F)_E.e DJoins (H|`F)_V.v,(H|`F)_V.w,H implies e DJoins v,w,G1
      by A18;
  end;
  thus F is Dcontinuous implies H |` F is Dcontinuous
  proof
    assume A19: F is Dcontinuous;
    now
      let e9,v,w be object;
      set f = (the_Vertices_of H) |` (F_V);
      assume A20: v in dom (H |` F)_V & w in dom (H |` F)_V &
        e9 DJoins (H |` F)_V.v,(H |` F)_V.w,H;
      then A21: v in dom f & w in dom f & e9 DJoins f.v,f.w,H;
      then A22: f.v = F_V.v & f.w = F_V.w by FUNCT_1:55;
      A23: v in dom F_V & F_V.v in the_Vertices_of H &
        w in dom F_V & F_V.w in the_Vertices_of H &
        v is set & w is set by A20, FUNCT_1:54;
      e9 DJoins F_V.v,F_V.w,G2 by A21, A22, GLIB_000:72;
      then consider e being object such that
        A24: e DJoins v,w,G1 & e in dom F_E & F_E.e = e9 by A19, A23;
      take e;
      thus e DJoins v,w,G1 by A24;
      e9 in the_Edges_of H by A20, GLIB_000:def 14;
      then e in dom ((the_Edges_of H) |` (F_E)) by A24, FUNCT_1:54;
      hence e in dom (H |` F)_E & (H |` F)_E.e = e9 by A24, FUNCT_1:55;
    end;
    hence thesis;
  end;
end;
