
theorem
  for G1 being _Graph, G2 being non-multi _Graph
  holds G2 is LGraphComplement of G1 iff
    the_Vertices_of G2 = the_Vertices_of G1 &
    the_Edges_of G2 misses the_Edges_of G1 &
    for v1,w1 being Vertex of G1, v2,w2 being Vertex of G2 st v1 = v2 & w1 = w2
    holds v1,w1 are_adjacent iff not v2,w2 are_adjacent
proof
  let G1 be _Graph, G2 be non-multi _Graph;
  hereby
    assume A1: G2 is LGraphComplement of G1;
    hence the_Vertices_of G2 = the_Vertices_of G1 &
      the_Edges_of G2 misses the_Edges_of G1 by Def7;
    let v1,w1 be Vertex of G1, v2,w2 be Vertex of G2;
    assume A2: v1 = v2 & w1 = w2;
    hereby
      assume v1,w1 are_adjacent;
      then ex e1 being object st e1 Joins v1,w1,G1 by CHORD:def 3;
      then not ex e2 being object st e2 Joins v1,w1,G2 by A1, Def7;
      hence not v2,w2 are_adjacent by A2, CHORD:def 3;
    end;
    assume not v2,w2 are_adjacent;
    then not ex e2 being object st e2 Joins v1,w1,G2 by A2, CHORD:def 3;
    then ex e1 being object st e1 Joins v1,w1,G1 by A1, Def7;
    hence v1,w1 are_adjacent by CHORD:def 3;
  end;
  assume that A3: the_Vertices_of G2 = the_Vertices_of G1 &
      the_Edges_of G2 misses the_Edges_of G1 and
    A4: for v1,w1 being Vertex of G1, v2,w2 being Vertex of G2
      st v1 = v2 & w1 = w2 holds v1,w1 are_adjacent iff not v2,w2 are_adjacent;
  now
    let v1,w1 be Vertex of G1;
    reconsider v2=v1, w2=w1 as Vertex of G2 by A3;
    hereby
      assume ex e1 being object st e1 Joins v1,w1,G1;
      then v1,w1 are_adjacent by CHORD:def 3;
      then not v2,w2 are_adjacent by A4;
      hence not ex e2 being object st e2 Joins v1,w1,G2 by CHORD:def 3;
    end;
    assume not ex e2 being object st e2 Joins v1,w1,G2;
    then not v2,w2 are_adjacent by CHORD:def 3;
    then v1,w1 are_adjacent by A4;
    hence ex e1 being object st e1 Joins v1,w1,G1 by CHORD:def 3;
  end;
  hence thesis by A3, Def7;
end;
