reserve a, b, c, d, r, s for Real,
  n for Element of NAT,
  p, p1, p2 for Point of TOP-REAL 2,
  x, y for Point of TOP-REAL n,
  C for Simple_closed_curve,
  A, B, P for Subset of TOP-REAL 2,
  U, V for Subset of (TOP-REAL 2)|C`,
  D for compact with_the_max_arc Subset of TOP-REAL 2;

theorem Th63:
  Proj2_2 is continuous Function of [:TOP-REAL 2, TOP-REAL 2:], R^1
proof
  reconsider fY2 = Proj2_2 as Function of [:T2,T2:],R^1 by TOPMETR:17;
  for p being Point of [:T2,T2:], V being Subset of R^1
  st fY2.p in V & V is open holds
  ex W being Subset of [:T2,T2:] st p in W & W is open & fY2.:W c= V
  proof
    let p be Point of [:T2,T2:], V be Subset of R^1 such that
A1: fY2.p in V and
A2: V is open;
A3: p = [p`1,p`2] by Lm5,MCART_1:21;
A4: fY2.p = p`2`2 by Def6;
    reconsider V1 = V as open Subset of REAL by A2,BORSUK_5:39,TOPMETR:17;
    consider g being Real such that
A5: 0 < g and
A6: ].p`2`2-g,p`2`2+g.[ c= V1 by A1,A4,RCOMP_1:19;
    reconsider g as Element of REAL by XREAL_0:def 1;
    set W1 = {|[x,y]| where x, y is Real:
    p`2`2-g < y & y < p`2`2+g};
    W1 c= the carrier of T2
    proof
      let a be object;
      assume a in W1;
      then ex x, y being Real st
      a = |[x,y]| & p`2`2-g < y & y < p`2`2+g;
      hence thesis;
    end;
    then reconsider W1 as Subset of T2;
    take [:[#]T2,W1:];
A7: p`2 = |[p`2`1,p`2`2]| by EUCLID:53;
A8: p`2`2-g < p`2`2-0 by A5,XREAL_1:15;
    p`2`2+0 < p`2`2+g by A5,XREAL_1:6;
    then p`2 in W1 by A7,A8;
    hence p in [:[#]T2,W1:] by A3,ZFMISC_1:def 2;
    W1 is open by PSCOMP_1:21;
    hence [:[#]T2,W1:] is open by BORSUK_1:6;
    let b be object;
    assume b in fY2.:[:[#]T2,W1:];
    then consider a being Point of [:T2,T2:] such that
A9: a in [:[#]T2,W1:] and
A10: fY2.a = b by FUNCT_2:65;
A11: a = [a`1,a`2] by Lm5,MCART_1:21;
A12: fY2.a = a`2`2 by Def6;
    a`2 in W1 by A9,A11,ZFMISC_1:87;
    then consider x1, y1 being Real such that
A13: a`2 = |[x1,y1]| and
A14: p`2`2-g < y1 and
A15: y1 < p`2`2+g;
A16: a`2`2 = y1 by A13,EUCLID:52;
A17: p`2`2-g+g < y1+g by A14,XREAL_1:6;
A18: p`2`2-y1 > p`2`2-(p`2`2+g) by A15,XREAL_1:15;
A19: p`2`2-y1 < y1+g-y1 by A17,XREAL_1:9;
    p`2`2-y1 > -g by A18;
    then |.p`2`2-y1.| < g by A19,SEQ_2:1;
    then |.-(p`2`2-y1).| < g by COMPLEX1:52;
    then |.y1-p`2`2.| < g;
    then a`2`2 in ].p`2`2-g,p`2`2+g.[ by A16,RCOMP_1:1;
    hence thesis by A6,A10,A12;
  end;
  hence thesis by JGRAPH_2:10;
end;
