reserve m,n,i,i2,j for Nat,
  r,r1,r2,s,t for Real,
  x,y,z for object;
reserve p,p1,p2,p3,q,q1,q2,q3,q4 for Point of TOP-REAL n;
reserve u for Point of Euclid n;

theorem Th48:
  for P, P1 being Subset of TOP-REAL n, Q being Subset of TOP-REAL
n, W being Subset of Euclid n st P=W & P is connected & W is not bounded & P1=
  Component_of (Down(P,Q`)) & W misses Q holds P1 is_outside_component_of Q
proof
  let P,P1 be Subset of TOP-REAL n, Q be Subset of TOP-REAL n, W be Subset of
  Euclid n;
  assume that
A1: P=W and
A2: P is connected and
A3: W is not bounded and
A4: P1=Component_of (Down(P,Q`)) and
A5: W misses Q;
A6: (TOP-REAL n) |P is connected by A2,CONNSP_1:def 3;
A7: (Down(P,Q`))=P \ Q by SUBSET_1:13
    .=P by A1,A5,XBOOLE_1:83;
  then reconsider P0=P as Subset of (TOP-REAL n) | Q`;
  reconsider W0=Component_of P0 as Subset of Euclid n by A4,A7,TOPREAL3:8;
  P0 c= Q` by A1,A5,SUBSET_1:23;
  then ((TOP-REAL n) | Q`) |P0=(TOP-REAL n) |P by PRE_TOPC:7;
  then
A8: P0 is connected by A6,CONNSP_1:def 3;
A9: now
    assume for D being Subset of Euclid n st D=P1 holds D is bounded;
    then W0 is bounded by A4,A7;
    hence contradiction by A1,A3,A8,CONNSP_3:1,TBSP_1:14;
  end;
A10: W <> {}Euclid n by A3;
A11: W /\ Q = {} by A5;
  now
    assume Q`={};
    then Q=({}(the carrier of TOP-REAL n))`;
    hence contradiction by A1,A10,A11,XBOOLE_1:28;
  end;
  then reconsider Q1=Q` as non empty Subset of TOP-REAL n;
  (TOP-REAL n) | Q1 is non empty;
  then Component_of P0 is a_component by A1,A10,A8,CONNSP_3:9;
  hence thesis by A4,A7,A9,Th8;
end;
