reserve T for non empty Abelian
  add-associative right_zeroed right_complementable RLSStruct,
  X,Y,Z,B,C,B1,B2 for Subset of T,
  x,y,p for Point of T;
reserve t,s,r1 for Real;
reserve n for Element of NAT;
reserve X,Y,B1,B2 for Subset of TOP-REAL n;
reserve x,y for Point of TOP-REAL n;

theorem Th63:
  t(.)(X (+) Y) = t(.)X (+) t(.)Y
proof
  thus t(.)(X (+) Y) c= t(.)X (+) t(.)Y
  proof
    let b be object;
    assume b in t(.)(X (+) Y);
    then consider a being Point of TOP-REAL n such that
A1: b = t*a and
A2: a in X (+) Y;
    consider x,y being Point of TOP-REAL n such that
A3: a=x+y and
A4: x in X & y in Y by A2;
A5: t*x in t(.)X & t*y in t(.)Y by A4;
    b=t*x+t*y by A1,A3,RLVECT_1:def 5;
    hence thesis by A5;
  end;
  let b be object;
  assume b in t(.)X (+) t(.)Y;
  then consider x,y being Point of TOP-REAL n such that
A6: b = x+y and
A7: x in t(.)X and
A8: y in t(.)Y;
  consider y1 being Point of TOP-REAL n such that
A9: y=t*y1 and
A10: y1 in Y by A8;
  consider x1 being Point of TOP-REAL n such that
A11: x=t*x1 and
A12: x1 in X by A7;
A13: x1+y1 in X (+) Y by A12,A10;
  b=t*(x1+y1) by A6,A11,A9,RLVECT_1:def 5;
  hence thesis by A13;
end;
