reserve i,j,k,n,l for Element of NAT,
  K for Field,
  a,b,c for Element of K,
  p ,q for FinSequence of K,
  M1,M2,M3 for Matrix of n,K;
reserve D for non empty set,
  t for FinSequence of D,
  A for Matrix of n,D;

theorem Th63:
  p is first-line-of-anti-circular implies ACirc(a*p) =a*(ACirc p)
proof
  set n=len p;
A1: len (a*p)=len p by MATRIXR1:16;
  assume
A2: p is first-line-of-anti-circular;
  then
A3: ACirc(p) is_anti-circular_about p by Def12;
  a*p is first-line-of-anti-circular by A2,Th62;
  then
A4: ACirc(a*p) is_anti-circular_about a*p by Def12;
A5: Indices ACirc(p) =[:Seg n, Seg n:] by MATRIX_0:24;
A6: for i,j be Nat st [i,j] in Indices ACirc(p) holds ACirc(a*p)*(i,j)=a*(
  ACirc(p)*(i,j))
  proof
    let i,j be Nat;
    assume
A7: [i,j] in Indices ACirc(p);
    then
A8: (j-i mod n)+1 in Seg n by A5,Lm3;
A9: [i,j] in Indices ACirc(a*p) by A1,A7,MATRIX_0:26;
    now
      per cases;
      case
A10:    i<=j;
A11:    dom (a*p)=Seg len (a*p) by FINSEQ_1:def 3;
A12:    dom p=Seg len p by FINSEQ_1:def 3;
        ACirc(a*p)*(i,j)=(a*p).((j-i mod len (a*p))+1) by A4,A9,A10
          .=(a*p)/.((j-i mod len p)+1) by A1,A8,A11,PARTFUN1:def 6
          .=a*(p/.((j-i mod len p)+1)) by A8,A12,POLYNOM1:def 1
          .=(a multfield).(p/.((j-i mod len p)+1)) by FVSUM_1:49
          .=(a multfield).(p.((j-i mod len p)+1)) by A8,A12,PARTFUN1:def 6
          .=(a multfield).(ACirc(p)*(i,j)) by A3,A7,A10
          .=a*(ACirc(p)*(i,j)) by FVSUM_1:49;
        hence thesis;
      end;
      case
A13:    i>=j;
        len (a*(-p))=len (-p) by MATRIXR1:16;
        then
A14:    dom (a*(-p))=Seg len (-p) by FINSEQ_1:def 3
          .=dom (-p) by FINSEQ_1:def 3;
A15:    a*p is Element of n-tuples_on the carrier of K by A1,FINSEQ_2:92;
A16:    p is Element of n-tuples_on the carrier of K by FINSEQ_2:92;
        then -p is Element of (len p)-tuples_on the carrier of K by
FINSEQ_2:113;
        then len (-p)=len p by CARD_1:def 7;
        then
A17:    dom (-p)=Seg n by FINSEQ_1:def 3;
        a*(ACirc(p)*(i,j)) =(a multfield).(ACirc(p)*(i,j)) by FVSUM_1:49
          .=(a multfield).((-p).((j-i mod len p)+1)) by A3,A7,A13
          .=(a multfield).((-p)/.((j-i mod len p)+1)) by A8,A17,PARTFUN1:def 6
          .=a*((-p)/.((j-i mod len p)+1)) by FVSUM_1:49
          .=(a*(-p))/.((j-i mod len p)+1) by A8,A17,POLYNOM1:def 1
          .=(a*(-p)).((j-i mod len p)+1) by A8,A17,A14,PARTFUN1:def 6
          .=(a*((-1_K)*p)).((j-i mod len p)+1) by A16,FVSUM_1:59
          .=((a*(-1_K))*p).((j-i mod len p)+1) by A16,FVSUM_1:54
          .=((-a*1_K)*p).((j-i mod len p)+1) by VECTSP_1:8
          .=((-a)*p).((j-i mod len p)+1)
          .=((-1_K*a)*p).((j-i mod len p)+1)
          .=(((-1_K)*a)*p).((j-i mod len p)+1) by VECTSP_1:9
          .=((-1_K)*(a*p)).((j-i mod len p)+1) by A16,FVSUM_1:54
          .=(-(a*p)).((j-i mod len p)+1) by A15,FVSUM_1:59
          .=ACirc(a*p)*(i,j) by A1,A4,A9,A13;
        hence thesis;
      end;
    end;
    hence thesis;
  end;
A18: len ACirc(p)= len p & width ACirc(p) = len p by MATRIX_0:24;
  len ACirc(a*p)= len p & width ACirc(a*p) = len p by A1,MATRIX_0:24;
  hence thesis by A18,A6,MATRIX_3:def 5;
end;
