reserve T for non empty TopSpace,
  A, B for Subset of T,
  F, G for Subset-Family of T;
reserve x for Point of T;

theorem Th63:
  for X being Subset-Family of T ex Y being all-open-containing
  compl-closed closed_for_countable_unions Subset-Family of T st X c= Y & for Z
  be all-open-containing compl-closed closed_for_countable_unions Subset-Family
  of T st X c= Z holds Y c= Z
proof
  let X be Subset-Family of T;
  set V = { S where S is Subset-Family of T : X c= S & S is
all-open-containing compl-closed closed_for_countable_unions Subset-Family of T
  };
  set Y = meet V;
A1: now
    let Z be set;
    assume Z in V;
    then ex S be Subset-Family of T st Z = S & X c= S & S is
all-open-containing compl-closed closed_for_countable_unions Subset-Family of T
    ;
    hence X c= Z;
  end;
A2: bool the carrier of T in V
  proof
    set X1 = TotFam T;
    X1 in V;
    hence thesis;
  end;
A3: for E being Subset of T st E in Y holds E` in Y
  proof
    let E be Subset of T such that
A4: E in Y;
    now
      let Z be set;
      assume Z in V;
      then E in Z & ex S being Subset-Family of T st Z = S & X c= S & S is
all-open-containing compl-closed closed_for_countable_unions Subset-Family of T
      by A4,SETFAM_1:def 1;
      hence E` in Z by PROB_1:def 1;
    end;
    hence thesis by A2,SETFAM_1:def 1;
  end;
A5: for BSeq be SetSequence of the carrier of T st rng BSeq c= Y holds
  Intersection BSeq in Y
  proof
    let BSeq be SetSequence of the carrier of T such that
A6: rng BSeq c= Y;
    now
      let Z be set;
      assume
A7:   Z in V;
      then consider S be Subset-Family of T such that
A8:   Z = S and
      X c= S and
A9:   S is all-open-containing compl-closed
      closed_for_countable_unions Subset-Family of T;
      now
        let n be Nat;
        BSeq.n in rng BSeq by NAT_1:51;
        hence BSeq.n in Z by A6,A7,SETFAM_1:def 1;
      end;
      then
A10:  rng BSeq c= Z by NAT_1:52;
      S is SigmaField of T by A9,Th13;
      hence Intersection BSeq in Z by A8,A10,PROB_1:def 6;
    end;
    hence thesis by A2,SETFAM_1:def 1;
  end;
  now
    let Z be set;
    assume Z in V;
    then ex S being Subset-Family of T st Z = S & X c= S & S is
all-open-containing compl-closed closed_for_countable_unions Subset-Family of T
    ;
    then Z is Field_Subset of the carrier of T by Th13;
    hence {} in Z by PROB_1:4;
  end;
  then {} in Y by A2,SETFAM_1:def 1;
  then reconsider Y as SigmaField of T by A2,A5,A3,PROB_1:15,SETFAM_1:3;
  for A being Subset of T st A is open holds A in Y
  proof
    let A be Subset of T;
    assume
A11: A is open;
    for Y being set holds Y in V implies A in Y
    proof
      let Y be set;
      assume Y in V;
      then ex S being Subset-Family of the carrier of T st Y = S & X c= S & S
is all-open-containing compl-closed closed_for_countable_unions Subset-Family
      of T;
      hence thesis by A11,Def2;
    end;
    hence thesis by A2,SETFAM_1:def 1;
  end;
  then reconsider
  Y as all-open-containing compl-closed closed_for_countable_unions
  Subset-Family of T by Def2;
  take Y;
  for Z be set st X c= Z & Z is all-open-containing compl-closed
  closed_for_countable_unions Subset-Family of T holds Y c= Z
  proof
    let Z be set;
    assume that
A12: X c= Z and
A13: Z is all-open-containing compl-closed closed_for_countable_unions
    Subset-Family of T;
    reconsider Z as Subset-Family of T by A13;
    Z in V by A12,A13;
    hence thesis by SETFAM_1:3;
  end;
  hence thesis by A2,A1,SETFAM_1:5;
end;
