reserve i,j,k,n,m for Nat,
  x,y,z,y1,y2 for object, X,Y,D for set,
  p,q for XFinSequence;
reserve k1,k2 for Nat;
reserve D for non empty set,
  F,G for XFinSequence of D,
  b for BinOp of D,
  d,d1,d2 for Element of D;
reserve F for XFinSequence,
        rF,rF1,rF2 for real-valued XFinSequence,
        r for Real,
        cF,cF1,cF2 for complex-valued XFinSequence,
        c,c1,c2 for Complex;

theorem
  c * Sum cF = Sum (c(#)cF)
proof
    defpred P[Nat] means for cF st len cF=$1 holds
  c * Sum cF = Sum (c(#)cF);
A1: for k st P[k] holds P[k+1]
  proof
    let k such that
A2: P[k];
A3: k<k+1 by NAT_1:13;
    let cF such that
A4: len cF=k+1;
    set cF1 = c(#)cF;
A5: dom cF=dom cF1 by VALUED_1:def 5;
    reconsider cF,cF1 as XFinSequence of COMPLEX;
A6: cF|(k+1)=cF by A4;
A7: len (cF|k)=k by A3,AFINSQ_1:11,A4;
    k<k+1 by NAT_1:13;
    then
A8: k in dom cF by A4,AFINSQ_1:86;
    then addcomplex.
      (addcomplex "**" cF|k, cF.k) = addcomplex "**" cF|(k+1) by Th42;
    then
A9: Sum cF=Sum (cF|k)+cF.k by A6,BINOP_2:def 3;
A10: c * Sum (cF|k)= Sum (c(#)(cF|k)) by A2,A7
        .= Sum(cF1|k) by Th62;
A11: c*cF.k=cF1.k by VALUED_1:6;
A12: cF1|(k+1)=cF1 by A4,A5;
    addcomplex.(addcomplex "**" cF1|k,cF1.k)
     =addcomplex "**" cF1|(k+1) by A5,A8,Th42;
    then Sum cF1=Sum (cF1|k)+cF1.k by A12,BINOP_2:def 3;
    hence thesis by A9,A11,A10;
  end;
A13: P[0]
  proof
    let cF such that
A14: len cF=0;
    set cF1 = c(#)cF;
      reconsider cF,cF1 as XFinSequence of COMPLEX;
A15: addcomplex "**" cF=0 by Def8,BINOP_2:1,A14;
    len cF1=0 by A14,VALUED_1:def 5;
    hence thesis by A15,Def8,BINOP_2:1;
  end;
 for k holds P[k] from NAT_1:sch 2(A13,A1);
  then P[len cF];
  hence thesis;
end;
