reserve a,a1,a2,b,c,d for Ordinal,
  n,m,k for Nat,
  x,y,z,t,X,Y,Z for set;
reserve f,g for Function;
reserve A,B,C for array;
reserve O for connected non empty Poset;
reserve R,Q for array of O;
reserve T for non empty array of O;
reserve p,q,r,s for Element of dom T;

theorem Th64:
  r in p & f = Swap(id dom T,p,q) implies
  (T,p,q)incl.(r,q) = [f.r,f.q] & (T,p,q)incl.(r,p) = [f.r,f.p]
  proof assume that
A1: r in p and
A2: f = Swap(id dom T,p,q);
    set X = dom T;
    set i = id X;
    set s = Swap(i,p,q);
    set h = [:s,s:];
    set Y = (succ q)\p;
    set Z1 = [:{p},Y:], Z2 = [:Y,{q}:];
    set g = id(Z1\/Z2);
    dom i = X; then
A3: dom s = X by FUNCT_7:99;
    not p c= r by A1,ORDINAL6:4; then
    r nin {p} & r nin Y by Th59,TARSKI:def 1; then
    [r,p] nin Z1 & [r,p] nin Z2 & [r,q] nin Z1 & [r,q] nin Z2
    by ZFMISC_1:87; then
A4: [r,q] nin dom g & [r,p] nin dom g by XBOOLE_0:def 3;
    hence (T,p,q)incl.(r,q) = h.(r,q) by FUNCT_4:11
    .= [f.r,f.q] by A2,A3,FUNCT_3:def 8;
    thus (T,p,q)incl.(r,p) = h.(r,p) by A4,FUNCT_4:11
    .= [f.r,f.p] by A2,A3,FUNCT_3:def 8;
  end;
