reserve r,x,x0,a,b for Real;
reserve n,m for Element of NAT;
reserve A for non empty closed_interval Subset of REAL;
reserve Z for open Subset of REAL;
reserve f, f1, f2, f3 for PartFunc of REAL, REAL;

theorem
  A c= Z & (for x st x in Z holds f.x = (cos.x-(sin.x)^2)/(sin.x)^2) & Z
c= dom (-cosec-id Z) & Z = dom f & f|A is continuous implies integral(f,A) =(-
  cosec-id Z).(upper_bound A)-(-cosec-id Z).(lower_bound A)
proof
  assume that
A1: A c= Z and
A2: for x st x in Z holds f.x = (cos.x-(sin.x)^2)/(sin.x)^2 and
A3: Z c= dom (-cosec-id Z) and
A4: Z = dom f and
A5: f|A is continuous;
A6: (-cosec-id Z) is_differentiable_on Z by A3,FDIFF_9:23;
A7: for x being Element of REAL
st x in dom ((-cosec-id Z)`|Z) holds ((-cosec-id Z)`|Z).x = f.x
  proof
    let x be Element of REAL;
    assume x in dom ((-cosec-id Z)`|Z);
    then
A8: x in Z by A6,FDIFF_1:def 7;
    then ((-cosec-id Z)`|Z).x = (cos.x-(sin.x)^2)/(sin.x)^2 by A3,FDIFF_9:23
      .= f.x by A2,A8;
    hence thesis;
  end;
  dom ((-cosec-id Z)`|Z) = dom f by A4,A6,FDIFF_1:def 7;
  then
A9: ((-cosec-id Z)`|Z) = f by A7,PARTFUN1:5;
  f is_integrable_on A & f|A is bounded by A1,A4,A5,INTEGRA5:10,11;
  hence thesis by A1,A3,A9,FDIFF_9:23,INTEGRA5:13;
end;
