reserve a, b, c, d, r, s for Real,
  n for Element of NAT,
  p, p1, p2 for Point of TOP-REAL 2,
  x, y for Point of TOP-REAL n,
  C for Simple_closed_curve,
  A, B, P for Subset of TOP-REAL 2,
  U, V for Subset of (TOP-REAL 2)|C`,
  D for compact with_the_max_arc Subset of TOP-REAL 2;

theorem Th64:
  for o, p being Point of TOP-REAL 2,
  r being positive Real st p is Point of Tdisk(o,r) holds
  DiskProj(o,r,p) is continuous
proof
  let o, p be Point of TOP-REAL 2;
  let r be positive Real such that
A1: p is Point of Tdisk(o,r);
  set D = Tdisk(o,r);
  set cB = cl_Ball(o,r);
  set Bp = cB \ {p};
  set OK = [:Bp,{p}:];
  set D1 = T2|Bp;
  set D2 = T2|{p};
  set S1 = Tcircle(o,r);
A2: p in {p} by TARSKI:def 1;
A3: the carrier of D = cl_Ball(o,r) by BROUWER:3;
A4: the carrier of D1 = Bp by PRE_TOPC:8;
A5: the carrier of D2 = {p} by PRE_TOPC:8;
  set TD = [:T2,T2:] | OK;
  set gg = DiskProj(o,r,p);
  set xo = diffX2_1(o);
  set yo = diffX2_2(o);
  set dx = diffX1_X2_1;
  set dy = diffX1_X2_2;
  set fx2 = Proj2_1;
  set fy2 = Proj2_2;
  reconsider rr = r^2 as Element of REAL by XREAL_0:def 1;
  set f1 = (the carrier of [:T2,T2:]) --> rr;
  reconsider f1 as continuous RealMap of [:T2,T2:] by Lm6;
  set Zf1 = f1 | OK;
  set Zfx2 = fx2 | OK;
  set Zfy2 = fy2 | OK;
  set Zdx = dx | OK;
  set Zdy = dy | OK;
  set Zxo = xo | OK;
  set Zyo = yo | OK;
  set xx = Zxo(#)Zdx;
  set yy = Zyo(#)Zdy;
  set m = Zdx(#)Zdx + Zdy(#)Zdy;
A6: the carrier of TD = OK by PRE_TOPC:8;
  A7: for y being Point of D1, z being Point of D2 holds Zdx. [y,z] = dx. [y,z]
  proof
    let y be Point of D1;
    let z be Point of D2;
    [y,z] in OK by A4,A5,ZFMISC_1:def 2;
    hence thesis by FUNCT_1:49;
  end;
  A8: for y being Point of D1, z being Point of D2 holds Zdy. [y,z] = dy. [y,z]
  proof
    let y be Point of D1;
    let z be Point of D2;
    [y,z] in OK by A4,A5,ZFMISC_1:def 2;
    hence thesis by FUNCT_1:49;
  end;
  A9: for
 y being Point of D1, z being Point of D2 holds Zfx2. [y,z] = fx2. [y,z]
  proof
    let y be Point of D1;
    let z be Point of D2;
    [y,z] in OK by A4,A5,ZFMISC_1:def 2;
    hence thesis by FUNCT_1:49;
  end;
  A10: for
 y being Point of D1, z being Point of D2 holds Zfy2. [y,z] = fy2. [y,z]
  proof
    let y be Point of D1;
    let z be Point of D2;
    [y,z] in OK by A4,A5,ZFMISC_1:def 2;
    hence thesis by FUNCT_1:49;
  end;
  A11: for
 y being Point of D1, z being Point of D2 holds Zf1. [y,z] = f1. [y,z]
  proof
    let y be Point of D1;
    let z be Point of D2;
    [y,z] in OK by A4,A5,ZFMISC_1:def 2;
    hence thesis by FUNCT_1:49;
  end;
  A12: for
 y being Point of D1, z being Point of D2 holds Zxo. [y,z] = xo. [y,z]
  proof
    let y be Point of D1;
    let z be Point of D2;
    [y,z] in OK by A4,A5,ZFMISC_1:def 2;
    hence thesis by FUNCT_1:49;
  end;
  A13: for
 y being Point of D1, z being Point of D2 holds Zyo. [y,z] = yo. [y,z]
  proof
    let y be Point of D1;
    let z be Point of D2;
    [y,z] in OK by A4,A5,ZFMISC_1:def 2;
    hence thesis by FUNCT_1:49;
  end;
  now
    let b be Real;
    assume b in rng m;
    then consider a being object such that
A14: a in dom m and
A15: m.a = b by FUNCT_1:def 3;
    consider y, z being object such that
A16: y in Bp and
A17: z in {p} and
A18: a = [y,z] by A14,ZFMISC_1:def 2;
A19: z = p by A17,TARSKI:def 1;
    reconsider y, z as Point of T2 by A16,A17;
A20: y <> z by A16,A19,ZFMISC_1:56;
A21: dx. [y,z] = [y,z]`1`1 - [y,z]`2`1 by Def3;
A22: dy. [y,z] = [y,z]`1`2 - [y,z]`2`2 by Def4;
    set r1 = y`1-z`1;
    set r2 = y`2-z`2;
A23: Zdx. [y,z] = dx. [y,z] by A4,A5,A7,A16,A17;
A24: Zdy. [y,z] = dy. [y,z] by A4,A5,A8,A16,A17;
  dom m c= the carrier of TD by RELAT_1:def 18;
  then
 a in the carrier of TD by A14;
  then
A25: m. [y,z] = (Zdx(#)Zdx). [y,z] + (Zdy(#)Zdy). [y,z] by A18,VALUED_1:1
      .= Zdx. [y,z] * Zdx. [y,z] + (Zdy(#)Zdy). [y,z] by VALUED_1:5
      .= r1^2+r2^2 by A21,A22,A23,A24,VALUED_1:5;
    now
      assume
A26:  r1^2+r2^2 = 0;
      then
A27:  r1 = 0 by COMPLEX1:1;
      r2 = 0 by A26,COMPLEX1:1;
      hence contradiction by A20,A27,TOPREAL3:6;
    end;
    hence 0 < b by A15,A18,A25;
  end;
  then reconsider m as positive-yielding continuous RealMap of TD
  by PARTFUN3:def 1;
  set p1 = (xx+yy)(#)(xx+yy);
  set p2 = Zxo(#)Zxo + Zyo(#)Zyo - Zf1;
A28: dom p2 = the carrier of TD by FUNCT_2:def 1;
  now
    let b be Real;
    assume b in rng p2;
    then consider a being object such that
A29: a in dom p2 and
A30: p2.a = b by FUNCT_1:def 3;
    consider y, z being object such that
A31: y in Bp and
A32: z in {p} and
A33: a = [y,z] by A29,ZFMISC_1:def 2;
    reconsider y, z as Point of T2 by A31,A32;
    set r3 = z`1-o`1, r4 = z`2-o`2;
A34: Zf1. [y,z] = f1. [y,z] by A4,A5,A11,A31,A32;
A35: Zxo. [y,z] = xo. [y,z] by A4,A5,A12,A31,A32;
A36: Zyo. [y,z] = yo. [y,z] by A4,A5,A13,A31,A32;
A37: xo. [y,z] = [y,z]`2`1 - o`1 by Def1;
A38: yo. [y,z] = [y,z]`2`2 - o`2 by Def2;
  dom p2 c= the carrier of TD by RELAT_1:def 18;
  then
A39: a in the carrier of TD by A29;
A40: p2. [y,z] = (Zxo(#)Zxo + Zyo(#)Zyo). [y,z] - Zf1. [y,z]
    by A29,A33,VALUED_1:13
      .= (Zxo(#)Zxo + Zyo(#)Zyo). [y,z] - r^2 by A34,FUNCOP_1:7
      .= (Zxo(#)Zxo). [y,z] + (Zyo(#)Zyo). [y,z] - r^2
                 by A33,A39,VALUED_1:1
      .= Zxo. [y,z] * Zxo. [y,z] + (Zyo(#)Zyo). [y,z] - r^2 by VALUED_1:5
      .= r3^2+r4^2-r^2 by A35,A36,A37,A38,VALUED_1:5;
    z = p by A32,TARSKI:def 1;
    then |. z-o .| <= r by A1,A3,TOPREAL9:8;
    then
A41: |. z-o .|^2 <= r^2 by SQUARE_1:15;
    |. z-o .|^2 = ((z-o)`1)^2+((z-o)`2)^2 by JGRAPH_1:29
      .= r3^2+((z-o)`2)^2 by TOPREAL3:3
      .= r3^2+r4^2 by TOPREAL3:3;
    then r3^2+r4^2-r^2 <= r^2-r^2 by A41,XREAL_1:9;
    hence 0 >= b by A30,A33,A40;
  end;
  then reconsider p2 as nonpositive-yielding continuous RealMap of TD
  by PARTFUN3:def 3;
  set pp = p1 - m(#)p2;
  set k = (-(xx+yy) + sqrt(pp)) / m;
  set x3 = Zfx2 + k(#)Zdx;
  set y3 = Zfy2 + k(#)Zdy;
  reconsider X3 = x3, Y3 = y3 as Function of TD,R^1 by TOPMETR:17;
  set F = <:X3,Y3:>;
  set R = R2Homeomorphism;
A42: for x being Point of D1 holds gg.x = (R*F). [x,p]
  proof
    let x be Point of D1;
    consider y being Point of T2 such that
A43: x = y and
A44: gg.x = HC(p,y,o,r) by A1,Def7;
A45: x <> p by A4,ZFMISC_1:56;
A46: [y,p] in OK by A2,A4,A43,ZFMISC_1:def 2;
    set r1 = y`1-p`1, r2 = y`2-p`2, r3 = p`1-o`1, r4 = p`2-o`2;
    set l = (-(r3*r1+r4*r2)+sqrt((r3*r1+r4*r2)^2-(r1^2+r2^2)*(r3^2+r4^2-r^2)))
    / (r1^2+r2^2);
A47: fx2. [y,p] = [y,p]`2`1 by Def5;
A48: fy2. [y,p] = [y,p]`2`2 by Def6;
A49: dx. [y,p] = [y,p]`1`1 - [y,p]`2`1 by Def3;
A50: dy. [y,p] = [y,p]`1`2 - [y,p]`2`2 by Def4;
A51: xo. [y,p] = [y,p]`2`1 - o`1 by Def1;
A52: yo. [y,p] = [y,p]`2`2 - o`2 by Def2;
A53: dom X3 = the carrier of TD by FUNCT_2:def 1;
A54: dom Y3 = the carrier of TD by FUNCT_2:def 1;
A55: dom pp = the carrier of TD by FUNCT_2:def 1;
A56: p is Point of D2 by A5,TARSKI:def 1;
    then
A57: Zdx. [y,p] = dx. [y,p] by A7,A43;
A58: Zdy. [y,p] = dy. [y,p] by A8,A43,A56;
A59: Zf1. [y,p] = f1. [y,p] by A11,A43,A56;
A60: Zxo. [y,p] = xo. [y,p] by A12,A43,A56;
A61: Zyo. [y,p] = yo. [y,p] by A13,A43,A56;
A62: m. [y,p] = (Zdx(#)Zdx). [y,p] + (Zdy(#)Zdy). [y,p] by A6,A46,VALUED_1:1
      .= Zdx. [y,p] * Zdx. [y,p] + (Zdy(#)Zdy). [y,p] by VALUED_1:5
      .= r1^2+r2^2 by A49,A50,A57,A58,VALUED_1:5;
A63: xx. [y,p] = Zxo. [y,p] * Zdx. [y,p] by VALUED_1:5;
A64: yy. [y,p] = Zyo. [y,p] * Zdy. [y,p] by VALUED_1:5;
A65: (xx+yy). [y,p] = xx. [y,p] + yy. [y,p] by A6,A46,VALUED_1:1;
    then
A66: p1. [y,p] = (r3*r1+r4*r2)^2
    by A49,A50,A51,A52,A57,A58,A60,A61,A63,A64,VALUED_1:5;
A67: p2. [y,p] = (Zxo(#)Zxo + Zyo(#)Zyo). [y,p] - Zf1. [y,p]
    by A6,A28,A46,VALUED_1:13
      .= (Zxo(#)Zxo + Zyo(#)Zyo). [y,p] - r^2 by A59,FUNCOP_1:7
      .= (Zxo(#)Zxo). [y,p] + (Zyo(#)Zyo). [y,p] - r^2 by A6,A46,VALUED_1:1
      .= Zxo. [y,p] * Zxo. [y,p] + (Zyo(#)Zyo). [y,p] - r^2 by VALUED_1:5
      .= r3^2+r4^2-r^2 by A51,A52,A60,A61,VALUED_1:5;
    dom sqrt pp = the carrier of TD by FUNCT_2:def 1;
    then
A68: sqrt(pp). [y,p] = sqrt(pp. [y,p]) by A6,A46,PARTFUN3:def 5
      .= sqrt(p1. [y,p] - (m(#)p2). [y,p]) by A6,A46,A55,VALUED_1:13
      .= sqrt((r3*r1+r4*r2)^2-(r1^2+r2^2)*(r3^2+r4^2-r^2))
    by A62,A66,A67,VALUED_1:5;
    dom k = the carrier of TD by FUNCT_2:def 1;
    then
A69: k. [y,p] = (-(xx+yy) + sqrt(pp)). [y,p] * (m. [y,p])" by A6,A46,
RFUNCT_1:def 1
      .= (-(xx+yy) + sqrt(pp)). [y,p] / m. [y,p] by XCMPLX_0:def 9
      .= ((-(xx+yy)). [y,p] + sqrt(pp). [y,p]) / (r1^2+r2^2)
    by A6,A46,A62,VALUED_1:1
      .= l by A49,A50,A51,A52,A57,A58,A60,A61,A63,A64,A65,A68,VALUED_1:8;
A70: X3. [y,p] = Zfx2. [y,p] + (k(#)Zdx). [y,p] by A6,A46,VALUED_1:1
      .= p`1 + (k(#)Zdx). [y,p] by A9,A43,A47,A56
      .= p`1+l*r1 by A49,A57,A69,VALUED_1:5;
A71: Y3. [y,p] = Zfy2. [y,p] + (k(#)Zdy). [y,p] by A6,A46,VALUED_1:1
      .= p`2 + (k(#)Zdy). [y,p] by A10,A43,A48,A56
      .= p`2+l*r2 by A50,A58,A69,VALUED_1:5;
A72: y in Bp by A4,A43;
    Bp c= cB by XBOOLE_1:36;
    hence gg.x = |[ p`1+l*r1, p`2+l*r2 ]| by A1,A3,A43,A44,A45,A72,BROUWER:8
      .= R. [X3. [y,p], Y3. [y,p]] by A70,A71,TOPREALA:def 2
      .= R.(F. [y,p]) by A6,A46,A53,A54,FUNCT_3:49
      .= (R*F). [x,p] by A6,A43,A46,FUNCT_2:15;
  end;
A73: X3 is continuous by JORDAN5A:27;
  Y3 is continuous by JORDAN5A:27;
  then reconsider F as continuous Function of TD,[:R^1,R^1:]
    by A73,YELLOW12:41;
  for pp being Point of D1, V being Subset of S1
  st gg.pp in V & V is open holds
  ex W being Subset of D1 st pp in W & W is open & gg.:W c= V
  proof
    let pp be Point of D1, V be Subset of S1 such that
A74: gg.pp in V and
A75: V is open;
    reconsider p1 = pp, fp = p as Point of T2 by PRE_TOPC:25;
A76: [pp,p] in OK by A2,A4,ZFMISC_1:def 2;
    consider V1 being Subset of T2 such that
A77: V1 is open and
A78: V1 /\ [#]S1 = V by A75,TOPS_2:24;
A79: gg.pp = (R*F). [pp,p] by A42;
    R" is being_homeomorphism by TOPREALA:34,TOPS_2:56;
    then
A80: R" .:V1 is open by A77,TOPGRP_1:25;
A81: dom F = the carrier of [:T2,T2:] | OK by FUNCT_2:def 1;
A82: dom R = the carrier of [:R^1,R^1:] by FUNCT_2:def 1;
    then
A83: rng F c= dom R;
    then
A84: dom (R*F) = dom F by RELAT_1:27;
A85: rng R = [#]T2 by TOPREALA:34,TOPS_2:def 5;
A86: R"*(R*F) = R"*R*F by RELAT_1:36
      .= id dom R*F by A85,TOPREALA:34,TOPS_2:52;
    dom id dom R = dom R;
    then
A87: dom (id dom R*F) = dom F by A83,RELAT_1:27;
    for x being object st x in dom F holds (id dom R*F).x = F.x
    proof
      let x be object such that
A88:  x in dom F;
A89:  F.x in rng F by A88,FUNCT_1:def 3;
      thus (id dom R*F).x = id dom R.(F.x) by A88,FUNCT_1:13
        .= F.x by A82,A89,FUNCT_1:18;
    end;
    then
A90: id dom R*F = F by A87,FUNCT_1:2;
    (R*F). [p1,fp] in V1 by A74,A78,A79,XBOOLE_0:def 4;
    then R" .((R*F). [p1,fp]) in R" .:V1 by FUNCT_2:35;
    then (R"*(R*F)). [p1,fp] in R" .:V1 by A6,A76,A81,A84,FUNCT_1:13;
    then consider W being Subset of TD such that
A91: [p1,fp] in W and
A92: W is open and
A93: F.:W c= R" .:V1 by A6,A76,A80,A86,A90,JGRAPH_2:10;
    consider WW being Subset of [:T2,T2:] such that
A94: WW is open and
A95: WW /\ [#]TD = W by A92,TOPS_2:24;
    consider SF being Subset-Family of [:T2,T2:] such that
A96: WW = union SF and
A97: for e being set st e in SF
    ex X1 being Subset of T2, Y1 being Subset of T2 st
    e = [:X1,Y1:] & X1 is open & Y1 is open by A94,BORSUK_1:5;
    [p1,fp] in WW by A91,A95,XBOOLE_0:def 4;
    then consider Z being set such that
A98: [p1,fp] in Z and
A99: Z in SF by A96,TARSKI:def 4;
    consider X1, Y1 being Subset of T2 such that
A100: Z = [:X1,Y1:] and
A101: X1 is open and Y1 is open by A97,A99;
    set ZZ = Z /\ [#]TD;
    reconsider XX = X1 /\ [#]D1 as open Subset of D1 by A101,TOPS_2:24;
    take XX;
    pp in X1 by A98,A100,ZFMISC_1:87;
    hence pp in XX by XBOOLE_0:def 4;
    thus XX is open;
    let b be object;
    assume b in gg.:XX;
    then consider a being Point of D1 such that
A102: a in XX and
A103: b = gg.a by FUNCT_2:65;
    reconsider a1 = a, fa = fp as Point of T2 by PRE_TOPC:25;
A104: a in X1 by A102,XBOOLE_0:def 4;
A105: [a,p] in OK by A2,A4,ZFMISC_1:def 2;
    fa in Y1 by A98,A100,ZFMISC_1:87;
    then [a,fa] in Z by A100,A104,ZFMISC_1:def 2;
    then [a,fa] in ZZ by A6,A105,XBOOLE_0:def 4;
    then
A106: F. [a1,fa] in F.:ZZ by FUNCT_2:35;
A107: R qua Function" = R" by TOPREALA:34,TOPS_2:def 4;
A108: dom(R") = [#]T2 by A85,TOPREALA:34,TOPS_2:49;
    Z c= WW by A96,A99,ZFMISC_1:74;
    then ZZ c= WW /\ [#]TD by XBOOLE_1:27;
    then F.:ZZ c= F.:W by A95,RELAT_1:123;
    then F. [a1,fa] in F.:W by A106;
    then R.(F. [a1,fa]) in R.:(R" .:V1) by A93,FUNCT_2:35;
    then (R*F). [a1,fa] in R.:(R" .:V1) by A6,A105,FUNCT_2:15;
    then (R*F). [a1,fa] in V1 by A107,A108,PARTFUN3:1,TOPREALA:34;
    then gg.a in V1 by A42;
    hence thesis by A78,A103,XBOOLE_0:def 4;
  end;
  hence thesis by JGRAPH_2:10;
end;
