reserve m,n,i,i2,j for Nat,
  r,r1,r2,s,t for Real,
  x,y,z for object;
reserve p,p1,p2,p3,q,q1,q2,q3,q4 for Point of TOP-REAL n;
reserve u for Point of Euclid n;

theorem Th49:
  for A being Subset of Euclid n, B being non empty Subset of
  Euclid n, C being Subset of (Euclid n) | B st A=C & C is bounded holds A is
  bounded
proof
  let A be Subset of Euclid n, B be non empty Subset of Euclid n, C be Subset
  of (Euclid n) | B;
  assume that
A1: A=C and
A2: C is bounded;
  consider r0 being Real such that
A3: 0<r0 and
A4: for x,y being Point of (Euclid n) | B st x in C & y in C holds dist(x,
  y)<=r0 by A2;
  for x,y being Point of (Euclid n) st x in A & y in A holds dist(x,y) <= r0
  proof
    let x,y be Point of (Euclid n);
    assume
A5: x in A & y in A;
    then reconsider x0=x,y0=y as Point of (Euclid n) | B by A1;
 (the distance of ((Euclid n) | B)).(x0,y0)= (the distance of (Euclid n))
.(x,y) & (the distance of ((Euclid n) | B)).(x0,y0)=dist(x0,y0)
      by TOPMETR:def 1;
    hence thesis by A1,A4,A5;
  end;
  hence thesis by A3;
end;
