reserve p,q,r,s,A,B for Element of PL-WFF,
  F,G,H for Subset of PL-WFF,
  k,n for Element of NAT,
  f,f1,f2 for FinSequence of PL-WFF;
reserve M for PLModel;

theorem exfin:
  for F,A holds
  F |- A iff ex G st G c= F & G is finite & G |- A
  proof
    let F,A;
    hereby
      assume F |- A;then
      consider f such that
A1:   f.len f=A & 1<=len f &
      for i be Nat st 1<=i & i<=len f holds prc f,F,i;
      deffunc h(Nat) = f.$1;
      set w2 = {i where i is Element of NAT: 1<=i & i<=len f};
      set G = {h(i) where i is Element of NAT: i in w2};
F1:   w2 c= Seg len f
      proof
        let x be object;
        assume x in w2;then
        consider i be Element of NAT such that
F2:     i = x & 1<=i<=len f;
        reconsider i1 = i as Nat;
        thus x in Seg len f by F2;
      end;
A8:   w2 is finite by F1;
A4:   G c= PL-WFF
      proof
        let x be object;
        assume x in G;then
        consider i be Element of NAT such that
A6:     x = h(i) & i in w2;
        consider j be Element of NAT such that
A9:     j = i & 1<=j & j<=len f by A6;
        i in dom f by FINSEQ_3:25,A9;then
A7:     x in rng f by A6,FUNCT_1:def 3;
        rng f c= PL-WFF by FINSEQ_1:def 4;
        hence x in PL-WFF by A7;
      end;
      G is finite from FRAENKEL:sch 21(A8);then
      reconsider G as finite Subset of PL-WFF by A4;
      now
        let i be Nat;
        assume
A6:     1<=i<=len f;then
        prc f,F,i by A1;then
        per cases;
        suppose f.i in PL_axioms;
          hence prc f,F/\G,i;
        end;
        suppose
A5:       f.i in F;
          reconsider i1 = i as Element of NAT by ORDINAL1:def 12;
          i1 in w2 by A6;then
          f.i in G;
          hence prc f,F/\G,i by A5,XBOOLE_0:def 4;
        end;
        suppose ex j,k be Nat
          st 1<=j & j<i & 1<=k & k<i & (f/.j,f/.k MP_rule f/.i);
          hence prc f,F/\G,i;
        end;
      end; then
      F /\ G |- A by A1;
      hence ex G st G c= F & G is finite & G |- A by XBOOLE_1:17;
    end;
    given G such that
A1: G c= F & G is finite & G |- A;
    thus F |- A by A1,monmp;
  end;
