reserve
  S for (4,1) integer bool-correct non empty non void BoolSignature,
  X for non-empty ManySortedSet of the carrier of S,
  T for vf-free integer all_vars_including inheriting_operations free_in_itself
  (X,S)-terms VarMSAlgebra over S,
  C for (4,1) integer bool-correct non-empty image of T,
  G for basic GeneratorSystem over S,X,T,
  A for IfWhileAlgebra of the generators of G,
  I for integer SortSymbol of S,
  x,y,z,m for pure (Element of (the generators of G).I),
  b for pure (Element of (the generators of G).the bool-sort of S),
  t,t1,t2 for Element of T,I,
  P for Algorithm of A,
  s,s1,s2 for Element of C-States(the generators of G);
reserve
  f for ExecutionFunction of A, C-States(the generators of G),
  (\falseC)-States(the generators of G, b);
reserve u for ManySortedFunction of FreeGen T, the Sorts of C;

theorem Th65:
  G is C-supported & f in C-Execution(A,b,\falseC) implies
  for a being SortSymbol of S, x being pure Element of (the generators of G).a
  for t being Element of T,a
  holds
  f.(s,x:=(t,A)).a.x = t value_at(C,s) &
  (for z being pure Element of (the generators of G).a st z <> x
  holds f.(s, x:=(t,A)).a.z = s.a.z) &
  for b being SortSymbol of S st a <> b holds
  (for z being pure Element of (the generators of G).b holds
  f.(s, x:=(t,A)).b.z = s.b.z)
  proof
    assume
A1: G is C-supported;
    assume
A2: f in C-Execution(A,b,\falseC);
    let a be SortSymbol of S;
    let x be pure Element of (the generators of G).a;
    let t be Element of T,a;
    reconsider x0 = @x as Element of G,a by AOFA_A00:def 22;
    thus
    f.(s, x:=(t,A)).a.x = succ(s,x0,t value_at(C,s)).a.x by A2,AOFA_A00:def 28
    .= t value_at(C,s) by A1,AOFA_A00:def 27;
    hereby
      let z be pure Element of (the generators of G).a; assume
A3:   z <> x;
A4:   x in (FreeGen T).a & z in (FreeGen T).a &
      FreeGen X is ManySortedSubset of the generators of G
      by A1,Def4;
      then vf @x = a-singleton(x) & FreeGen X c= the generators of G
      by AOFA_A00:41,PBOOLE:def 18;
      then (vf @x).a = {x} & (FreeGen X).a c= (the generators of G).a
      by AOFA_A00:6;
      then
A5:   z nin (vf @x).a & @x is Element of G,a
      by A3,TARSKI:def 1,AOFA_A00:def 22;
      thus f.(s, x:=(t,A)).a.z = succ(s,x0,t value_at(C,s)).a.z
      by A2,AOFA_A00:def 28
      .= s.a.z by A1,A3,A5,A4,AOFA_A00:def 27;
    end;
    let b be SortSymbol of S; assume
A6: a <> b;
    hereby
      let z be pure Element of (the generators of G).b;
A7:   x in (FreeGen T).a & z in (FreeGen T).b &
      FreeGen X is ManySortedSubset of the generators of G
      by A1,Def4;
      then vf @x = a-singleton(x) & FreeGen X c= the generators of G
      by AOFA_A00:41,PBOOLE:def 18;
      then
A8:   z nin (vf @x).b & @x is Element of G,a
      by A6,AOFA_A00:6,AOFA_A00:def 22;
      thus f.(s, x:=(t,A)).b.z = succ(s,x0,t value_at(C,s)).b.z
      by A2,AOFA_A00:def 28
      .= s.b.z by A1,A6,A8,A7,AOFA_A00:def 27;
    end;
  end;
