reserve n for Nat,
  i,j for Nat,
  r,s,r1,s1,r2,s2,r9,s9 for Real,
  p,q for Point of TOP-REAL 2,
  G for Go-board,
  x,y for set,
  v for Point of Euclid 2;

theorem
  1 <= j & j < width G & 1 <= i & i+1 < len G implies LSeg(1/2*(G*(i,j)+
G*(i+1,j+1)),1/2*(G*(i+1,j)+G*(i+2,j+1))) c= Int cell(G,i,j) \/ Int cell(G,i+1,
  j) \/ { 1/2*(G*(i+1,j)+G*(i+1,j+1)) }
proof
  assume that
A1: 1 <= j and
A2: j < width G and
A3: 1 <= i and
A4: i+1 < len G;
  set p1 = G*(i,j), p2 = G*(i+1,j), q2 = G*(i+1,j+1), q3 = G*(i+2,j+1), r = (
  p2`1-p1`1)/(q3`1-p1`1);
A5: i+1 >= 1 by NAT_1:11;
  set I1 = Int cell(G,i,j), I2 = Int cell(G,i+1,j);
  i <= i+1 by NAT_1:11;
  then
A6: i < len G by A4,XXREAL_0:2;
  then
A7: LSeg(1/2*(p1+q2),1/2*(p2+q2)) c= I1 \/ { 1/2*(p2+q2) } by A1,A2,A3,Th42;
  i < i+1 by XREAL_1:29;
  then p1`1 < p2`1 by A1,A2,A3,A4,GOBOARD5:3;
  then
A8: p2`1-p1`1 > 0 by XREAL_1:50;
A9: i+1+1 = i+(1+1);
  then
A10: i+2 >= 1 by NAT_1:11;
A11: i+(1+1) <= len G by A4,A9,NAT_1:13;
A12: j+1 >= 1 & j+1 <= width G by A2,NAT_1:11,13;
  then
A13: q2`2 = G*(1,j+1)`2 by A4,A5,GOBOARD5:1
    .= q3`2 by A11,A10,A12,GOBOARD5:1;
A14: q2`1 = G*(i+1,1)`1 by A4,A5,A12,GOBOARD5:2
    .= p2`1 by A1,A2,A4,A5,GOBOARD5:2;
  i+1 < i+2 by XREAL_1:6;
  then q2`1 < q3`1 by A5,A11,A12,GOBOARD5:3;
  then
A15: p2`1-p1`1 < q3`1-p1`1 by A14,XREAL_1:9;
  then
A16: r*(q3`1-p1`1) = p2`1-p1`1 by A8,XCMPLX_1:87;
  p1`2 = G*(1,j)`2 by A1,A2,A3,A6,GOBOARD5:1
    .= p2`2 by A1,A2,A4,A5,GOBOARD5:1;
  then
A17: (p2+q2)`2 = (1-r)*(p1`2+q2`2)+r*(p2`2+q3`2) by A13,Lm1
    .= (1-r)*(p1+q2)`2+r*(p2`2+q3`2) by Lm1
    .= (1-r)*(p1+q2)`2+r*(p2+q3)`2 by Lm1
    .= (1-r)*(p1+q2)`2+(r*(p2+q3))`2 by Lm3
    .= ((1-r)*(p1+q2))`2+(r*(p2+q3))`2 by Lm3
    .= ((1-r)*(p1+q2)+r*(p2+q3))`2 by Lm1;
  (p2+q2)`1 = p2`1+(r+(1-r))*q2`1 by Lm1
    .= (1-r)*(p1`1+q2`1)+r*(p2`1+q3`1) by A14,A16
    .= (1-r)*(p1`1+q2`1)+r*(p2+q3)`1 by Lm1
    .= (1-r)*(p1+q2)`1+r*(p2+q3)`1 by Lm1
    .= (1-r)*(p1+q2)`1+(r*(p2+q3))`1 by Lm3
    .= ((1-r)*(p1+q2))`1+(r*(p2+q3))`1 by Lm3
    .= ((1-r)*(p1+q2)+r*(p2+q3))`1 by Lm1;
  then (1-r)*(p1+q2)+r*(p2+q3) = |[(p2+q2)`1,(p2+q2)`2]| by A17,EUCLID:53
    .= p2+q2 by EUCLID:53;
  then
A18: 1/2*(p2+q2) = (1/2)*((1-r)*(p1+q2))+(1/2)*(r*(p2+q3)) by RLVECT_1:def 5
    .= 1/2*(1-r)*(p1+q2)+1/2*(r*(p2+q3)) by RLVECT_1:def 7
    .= (1-r)*(1/2*(p1+q2))+1/2*(r*(p2+q3)) by RLVECT_1:def 7
    .= (1-r)*(1/2*(p1+q2))+1/2*r*(p2+q3) by RLVECT_1:def 7
    .= (1-r)*((1/2)*(p1+q2))+r*((1/2)*(p2+q3)) by RLVECT_1:def 7;
  r < 1 by A15,A8,XREAL_1:189;
  then 1/2*(p2+q2) in LSeg(1/2*(p1+q2),1/2*(p2+q3)) by A15,A8,A18;
  then
A19: LSeg(1/2*(p1+q2),1/2*(p2+q3)) = LSeg(1/2*(p1+q2),1/2*(p2+q2)) \/ LSeg(1
  /2*(p2+q2),1/2*(p2+q3)) by TOPREAL1:5;
A20: I1 \/ I2 \/ { 1/2*(p2+q2) } = I1 \/ (I2 \/ ({ 1/2*(p2+q2) } \/ { 1/2*(
  p2+q2) })) by XBOOLE_1:4
    .= I1 \/ (I2 \/ { 1/2*(p2+q2) } \/ { 1/2*(p2+q2) }) by XBOOLE_1:4
    .= I1 \/ { 1/2*(p2+q2) } \/ (I2 \/ { 1/2*(p2+q2) }) by XBOOLE_1:4;
  LSeg(1/2*(p2+q2),1/2*(p2+q3)) c= I2 \/ { 1/2*(p2+q2) } by A1,A2,A4,A5,A9,Th40
;
  hence thesis by A19,A7,A20,XBOOLE_1:13;
end;
