reserve X for set,
        n,m,k for Nat,
        K for Field,
        f for n-element real-valued FinSequence,
        M for Matrix of n,m,F_Real;

theorem
  for K be Field,
    V,W be finite-dimensional VectSp of K
  holds
    dim V = dim W
      iff
    ex T be linear-transformation of V, W st T is bijective
  proof
    let K be Field,
        V,W be finite-dimensional VectSp of K;

    hereby
      assume
      A1: dim V = dim W;
      consider T1 be linear-transformation of V, (dim V) -VectSp_over K
      such that
      A2: T1 is bijective by Th64;

      consider T2 be linear-transformation of W, (dim V) -VectSp_over K
      such that
      A3: T2 is bijective by A1,Th64;

      consider S be linear-transformation of (dim V) -VectSp_over K,W
      such that
      A4: (S = T2 " & S is bijective) by A3,ZMODUL06:42;
      set T = S * T1;
      reconsider T as linear-transformation of V, W;
      T is bijective by A2,A4,FINSEQ_4:85;

      hence
      ex T be linear-transformation of V, W st T is bijective;
    end;
    assume ex T be linear-transformation of V, W st T is bijective;
    hence dim V = dim W by VECTSP12:4;
  end;
