reserve n,m for Nat,
  r,r1,r2,s,t for Real,
  x,y for set;

theorem Th65:
  for D be non empty set, d be Element of D, X be set,
      F be PartFunc of D,REAL st
    X is finite & d in dom(F|X) holds
    FinS(F,X\{d})^<*F.d*>, F|X are_fiberwise_equipotent
proof
  for D be non empty set, X be finite set, F be PartFunc of D,REAL, x be
object st x in dom(F|X)
holds FinS(F,X\{x})^<*F.x*>, F|X are_fiberwise_equipotent
  proof
    let D be non empty set, X be finite set, F be PartFunc of D,REAL,
        x be object;
    set Y = X \ {x};
    set A = FinS(F,Y)^<* F.x *>;
    assume x in dom(F|X);
    then
A1: x in dom F /\ X by RELAT_1:61;
    then x in X by XBOOLE_0:def 4;
    then
A2: {x} c= X by ZFMISC_1:31;
    x in dom F by A1,XBOOLE_0:def 4;
    then
A3: {x} c= dom F by ZFMISC_1:31;
    dom(F|Y) is finite;
    then
A4: F|Y, FinS(F,Y) are_fiberwise_equipotent by Def13;
    now
      let y be object;
A5:   Y misses {x} by XBOOLE_1:79;
A6:   card Coim(F|Y,y) = card Coim(FinS(F,Y),y) by A4,CLASSES1:def 10;
A7:   dom(F|{x}) = {x} by A3,RELAT_1:62;
A8:   dom<*F.x*> = {1} by FINSEQ_1:2,38;
A9:   now
        per cases;
        case
A10:      y=F.x;
A11:      {x} c= (F|{x})"{y}
          proof
            let z be object;
A12:        y in {y} by TARSKI:def 1;
            assume
A13:        z in {x};
            then z=x by TARSKI:def 1;
            then y=(F|{x}).z by A7,A10,A13,FUNCT_1:47;
            hence thesis by A7,A13,A12,FUNCT_1:def 7;
          end;
          (F|{x})"{y} c= {x} by A7,RELAT_1:132;
          then (F|{x})"{y} = {x} by A11;
          then
A14:      card((F|{x})"{y}) = 1 by CARD_1:30;
A15:      {1} c= <*F.x*>"{y}
          proof
            let z be object;
A16:        y in {y} by TARSKI:def 1;
            assume
A17:        z in {1};
            then z=1 by TARSKI:def 1;
            then y=<*F.x*>.z by A10;
            hence thesis by A8,A17,A16,FUNCT_1:def 7;
          end;
          <*F.x*>"{y} c= {1} by A8,RELAT_1:132;
          then <*F.x*>"{y} = {1} by A15;
          hence card((F|{x})"{y}) = card(<*F.x*>"{y}) by A14,CARD_1:30;
        end;
        case
A18:      y <> F.x;
A19:      now
            set z = the Element of <*F.x*>"{y};
            assume
A20:        <*F.x*>"{y} <> {};
            then <*F.x*>.z in {y} by FUNCT_1:def 7;
            then
A21:        <*F.x*>.z=y by TARSKI:def 1;
            z in {1} by A8,A20,FUNCT_1:def 7;
            then z=1 by TARSKI:def 1;
            hence contradiction by A18,A21;
          end;
          now
            set z = the Element of (F|{x})"{y};
            assume
A22:        (F|{x})"{y} <> {};
            then (F|{x}).z in {y} by FUNCT_1:def 7;
            then
A23:        (F|{x}).z=y by TARSKI:def 1;
A24:        z in {x} by A7,A22,FUNCT_1:def 7;
            then z=x by TARSKI:def 1;
            hence contradiction by A7,A18,A24,A23,FUNCT_1:47;
          end;
          hence card((F|{x})"{y}) = card(<*F.x*>"{y}) by A19;
        end;
      end;
A25:  (F|Y)"{y} \/ (F|{x})"{y} = (Y /\ F"{y}) \/ (F|{x})"{y} by FUNCT_1:70
        .= (Y /\ F"{y}) \/ ({x} /\ F"{y}) by FUNCT_1:70
        .= (Y \/ {x}) /\ F"{y} by XBOOLE_1:23
        .= (X \/ {x}) /\ F"{y} by XBOOLE_1:39
        .= X /\ F"{y} by A2,XBOOLE_1:12
        .= (F|X)"{y} by FUNCT_1:70;
      (F|Y)"{y} /\ (F|{x})"{y} = Y /\ (F"{y}) /\ (F|{x})"{y} by FUNCT_1:70
        .= Y /\ F"{y} /\ ({x} /\ F"{y}) by FUNCT_1:70
        .= F"{y} /\ Y /\ {x} /\ F"{y} by XBOOLE_1:16
        .= F"{y} /\ (Y /\ {x}) /\ F"{y} by XBOOLE_1:16
        .= {} /\ F"{y} by A5
        .= {};
      hence
      card Coim(F|X,y) = card((F|Y)"{y}) + card(<*F.x*>"{y}) - card {} by A25
,A9,CARD_2:45
        .= card Coim(A,y) by A6,FINSEQ_3:57;
    end;
    hence thesis by CLASSES1:def 10;
  end;
  hence thesis;
end;
