
theorem Th66:
  for G1, G2 being _Graph
  for G3 being removeParallelEdges of G1, G4 being removeParallelEdges of G2
  for G5 being LGraphComplement of G1, G6 being LGraphComplement of G2
  st G4 is G3-isomorphic holds G6 is G5-isomorphic
proof
  let G1, G2 be _Graph;
  let G3 be removeParallelEdges of G1, G4 be removeParallelEdges of G2;
  let G5 be LGraphComplement of G1, G6 be LGraphComplement of G2;
  A1: G5 is LGraphComplement of G3 & G6 is LGraphComplement of G4 by Th65;
  assume G4 is G3-isomorphic;
  then consider f being PVertexMapping of G3, G4 such that
    A2: f is isomorphism by GLIB_011:49;
  A3: the_Vertices_of G3 = the_Vertices_of G5 &
    the_Vertices_of G4 = the_Vertices_of G6 by A1, Def7;
  then reconsider g = f as PartFunc of the_Vertices_of G5, the_Vertices_of G6;
  now
    let v,w,e be object;
    assume A4: v in dom g & w in dom g & e Joins v,w,G5;
    then A5: not ex e3 being object st e3 Joins v,w,G3 by A1, A3, Def7;
    thus ex e6 being object st e6 Joins g.v,g.w,G6
    proof
      assume A6: not ex e6 being object st e6 Joins g.v,g.w,G6;
      g.v in rng f & g.w in rng f by A4, FUNCT_1:3;
      then consider e4 being object such that
        A7: e4 Joins g.v,g.w,G4 by A1, A6, Def7;
      consider e3 being object such that
        A8: e3 Joins v,w,G3 by A2, A4, A7, GLIB_011:2;
      thus contradiction by A5, A8;
    end;
  end;
  then reconsider g as PVertexMapping of G5, G6 by GLIB_011:1;
  now
    let v,w,e6 be object;
    assume A9: v in dom g & w in dom g & e6 Joins g.v,g.w,G6;
    g.v in rng f & g.w in rng f by A9, FUNCT_1:3;
    then A10: not ex e4 being object st e4 Joins g.v,g.w,G4 by A1, A9, Def7;
    thus ex e5 being object st e5 Joins v,w,G5
    proof
      assume not ex e5 being object st e5 Joins v,w,G5;
      then consider e3 being object such that
        A11: e3 Joins v,w,G3 by A1, A3, A9, Def7;
      consider e4 being object such that
        A12: e4 Joins f.v,f.w,G4 by A9, A11, GLIB_011:1;
      thus contradiction by A10, A12;
    end;
  end;
  then g is continuous by GLIB_011:2;
  hence thesis by A2, A3, GLIB_011:49;
end;
