reserve r,x,x0,a,b for Real;
reserve n,m for Element of NAT;
reserve A for non empty closed_interval Subset of REAL;
reserve Z for open Subset of REAL;
reserve f, f1, f2, f3 for PartFunc of REAL, REAL;

theorem
  A c= Z & Z c= ]. -1,1 .[ & (for x st x in Z holds f.x=arcsin.x/sqrt(1-
  x^2)) & Z c= dom ((1/2)(#)(( #Z 2)*(arcsin))) & Z = dom f & f|A is continuous
implies integral(f,A) = ((1/2)(#)(( #Z 2)*(arcsin))).(upper_bound A)
 -((1/2)(#)(( #Z 2)
  *(arcsin))).(lower_bound A)
proof
  assume that
A1: A c= Z and
A2: Z c= ]. -1,1 .[ and
A3: for x st x in Z holds f.x=arcsin.x/sqrt(1-x^2) and
A4: Z c= dom ((1/2)(#)(( #Z 2)*(arcsin))) and
A5: Z = dom f and
A6: f|A is continuous;
A7: ((1/2)(#)(( #Z 2)*(arcsin))) is_differentiable_on Z by A2,A4,FDIFF_7:12;
A8: for x being Element of REAL
st x in dom (((1/2)(#)(( #Z 2)*(arcsin)))`|Z) holds (((1/2)(#)(( #Z
  2)*(arcsin)))`|Z).x = f.x
  proof
    let x be Element of REAL;
    assume x in dom (((1/2)(#)(( #Z 2)*(arcsin)))`|Z);
    then
A9: x in Z by A7,FDIFF_1:def 7;
    then
    (((1/2)(#)(( #Z 2)*(arcsin)))`|Z).x = arcsin.x / sqrt(1-x^2) by A2,A4,
FDIFF_7:12
      .= f.x by A3,A9;
    hence thesis;
  end;
  dom (((1/2)(#)(( #Z 2)*(arcsin)))`|Z) = dom f by A5,A7,FDIFF_1:def 7;
  then
A10: (((1/2)(#)(( #Z 2)*(arcsin)))`|Z) = f by A8,PARTFUN1:5;
  f is_integrable_on A & f|A is bounded by A1,A5,A6,INTEGRA5:10,11;
  hence thesis by A1,A2,A4,A10,FDIFF_7:12,INTEGRA5:13;
end;
