
theorem Th66:
  for S,T being complete LATTICE
  for d being sups-preserving Function of T,S holds d is compact-preserving
  iff d|the carrier of CompactSublatt T is
  finite-sups-preserving Function of CompactSublatt T, CompactSublatt S
proof
  let S,T be complete LATTICE, d be sups-preserving Function of T,S;
  thus
  d is compact-preserving implies d|the carrier of CompactSublatt T is
  finite-sups-preserving Function of CompactSublatt T, CompactSublatt S
  proof
    assume
A1: for x being Element of T st x is compact holds d.x is compact;
    d.:the carrier of CompactSublatt T c= the carrier of CompactSublatt S
    proof
      let y be object;
      assume y in d.: the carrier of CompactSublatt T;
      then consider x being object such that
A2:   x in the carrier of T and
A3:   x in the carrier of CompactSublatt T and
A4:   y = d.x by FUNCT_2:64;
      reconsider x as Element of T by A2;
      x is compact by A3,WAYBEL_8:def 1;
      then d.x is compact by A1;
      hence thesis by A4,WAYBEL_8:def 1;
    end;
    hence thesis by Th63,Th65;
  end;
  assume
A5: d|the carrier of CompactSublatt T is
  finite-sups-preserving Function of CompactSublatt T, CompactSublatt S;
  let x be Element of T;
  assume x is compact;
  then
A6: x in the carrier of CompactSublatt T by WAYBEL_8:def 1;
  then d.x = (d|the carrier of CompactSublatt T).x by FUNCT_1:49;
  then d.x in the carrier of CompactSublatt S by A5,A6,FUNCT_2:5;
  hence thesis by WAYBEL_8:def 1;
end;
