reserve p,p1,p2,p3,q,q1,q2 for Point of TOP-REAL 2,
  i for Nat,
  lambda for Real;

theorem Th67:
  for p being Point of TOP-REAL 2, f being Function of TOP-REAL 2,TOP-REAL 2 st
  f=Sq_Circ & p`1=-1 & p`2<0 holds (f.p)`1<0 & (f.p)`2<0
proof
  let p be Point of TOP-REAL 2, f be Function of TOP-REAL 2,TOP-REAL 2;
  assume that
A1: f=Sq_Circ and
A2: p`1=-1 and
A3: p`2<0;
  now per cases;
    case p=0.TOP-REAL 2;
      hence contradiction by A2,EUCLID:52,54;
    end;
    case
A4:   p<> 0.TOP-REAL 2;
      now per cases;
        case p`2<=p`1 & -p`1<=p`2 or p`2>=p`1 & p`2<=-p`1;
          then
A5:       f.p=|[p`1/sqrt(1+(p`2/p`1)^2),p`2/sqrt(1+(p`2/p`1)^2)]|
          by A1,A4,JGRAPH_3:def 1;
          then
A6:       (f.p)`1= p`1/sqrt(1+(p`2/p`1)^2) by EUCLID:52;
          (f.p)`2= p`2/sqrt(1+(p`2/p`1)^2) by A5,EUCLID:52;
          hence thesis by A2,A3,A6,SQUARE_1:25,XREAL_1:141;
        end;
        case not (p`2<=p`1 & -p`1<=p`2 or p`2>=p`1 & p`2<=-p`1);
          then
A7:       f.p=|[p`1/sqrt(1+(p`1/p`2)^2),p`2/sqrt(1+(p`1/p`2)^2)]|
          by A1,A4,JGRAPH_3:def 1;
          then
A8:       (f.p)`1= p`1/sqrt(1+(p`1/p`2)^2) by EUCLID:52;
          (f.p)`2= p`2/sqrt(1+(p`1/p`2)^2) by A7,EUCLID:52;
          hence thesis by A2,A3,A8,SQUARE_1:25,XREAL_1:141;
        end;
      end;
      hence thesis;
    end;
  end;
  hence thesis;
end;
