
theorem Th67:
  for a,b,c,d being Real, h being Function of TOP-REAL 2,
TOP-REAL 2,f being Function of I[01],TOP-REAL 2, O,I being Point of I[01] st a<
b & h=AffineMap(2/(b-a),-(b+a)/(b-a),2/(d-c),-(d+c)/(d-c)) & a <(f.I)`1 & (f.I)
`1 <(f.O)`1 & (f.O)`1<=b holds -1<((h*f).I)`1 & ((h*f).I)`1<((h*f).O)`1 & ((h*f
  ).O)`1<=1
proof
  let a,b,c,d be Real, h be Function of TOP-REAL 2,TOP-REAL 2,f be
  Function of I[01],TOP-REAL 2, O,I be Point of I[01];
  set A=2/(b-a), B=-(b+a)/(b-a), C = 2/(d-c), D=-(d+c)/(d-c);
  assume that
A1: a<b and
A2: h=AffineMap(A,B,C,D) and
A3: a <(f.I)`1 and
A4: (f.I)`1 <(f.O)`1 and
A5: (f.O)`1<=b;
A6: (h.(f.O))= |[A*((f.O)`1)+B,C*((f.O)`2)+D]| by A2,JGRAPH_2:def 2;
A7: b-a>0 by A1,XREAL_1:50;
  then
A8: A >0 by XREAL_1:139;
  (1-B)/A =(1+(b+a)/(b-a))/(2/(b-a))
    .=((1)*(b-a)+(b+a))/(b-a)/(2/(b-a)) by A7,XCMPLX_1:113
    .= (b-a)*((b+b)/(b-a)/2) by XCMPLX_1:82
    .= ((b-a)*((b+b)/(b-a)))/2
    .=(b+b)/2 by A7,XCMPLX_1:87
    .= b;
  then A*((1- B)/A) >= A*((f.O)`1) by A5,A8,XREAL_1:64;
  then 1-B >= A*((f.O)`1) by A8,XCMPLX_1:87;
  then
A9: 1-B+B >= A*((f.O)`1)+B by XREAL_1:6;
A10: dom f=the carrier of I[01] by FUNCT_2:def 1;
  then
A11: ((h*f).O)=(h.(f.O)) by FUNCT_1:13;
A12: ((h*f).I)=(h.(f.I)) by A10,FUNCT_1:13;
  (-1-B)/A =(-1+(b+a)/(b-a))/(2/(b-a))
    .=((-1)*(b-a)+(b+a))/(b-a)/(2/(b-a)) by A7,XCMPLX_1:113
    .= (b-a)*((a+a)/(b-a)/2) by XCMPLX_1:82
    .= ((b-a)*((a+a)/(b-a)))/2
    .=(a+a)/2 by A7,XCMPLX_1:87
    .= a;
  then A*((-1-B)/A) < A*((f.I)`1) by A3,A8,XREAL_1:68;
  then -1-B < A*((f.I)`1) by A8,XCMPLX_1:87;
  then
A13: -1-B+B < A*((f.I)`1)+B by XREAL_1:8;
A14: (h.(f.I))= |[A*((f.I)`1)+B,C*((f.I)`2)+D]| by A2,JGRAPH_2:def 2;
  A*((f.O)`1)> A*((f.I)`1) by A4,A8,XREAL_1:68;
  then A*((f.O)`1)+B > A*((f.I)`1)+B by XREAL_1:8;
  then A*((f.O)`1)+B > ((h*f).I)`1 by A12,A14,EUCLID:52;
  hence thesis by A11,A12,A6,A14,A9,A13,EUCLID:52;
end;
