reserve m,n,i,i2,j for Nat,
  r,r1,r2,s,t for Real,
  x,y,z for object;
reserve p,p1,p2,p3,q,q1,q2,q3,q4 for Point of TOP-REAL n;
reserve u for Point of Euclid n;

theorem Th52:
  for r being Real holds (ex B being Subset of Euclid n st B={q :
(|.q.|) < r }) & for A being Subset of Euclid n st A={q1 : (|.q1.|) < r } holds
  A is bounded
proof
  let r be Real;
A1: {q : (|.q.|) < r } c= the carrier of Euclid n
  proof
    let x be object;
    assume x in {q : (|.q.|) < r };
    then ex q being Point of TOP-REAL n st q=x & (|.q.|) < r;
    then x in the carrier of TOP-REAL n;
    hence thesis by TOPREAL3:8;
  end;
  hence ex B being Subset of Euclid n st B={q : (|.q.|) < r };
  reconsider C={q1 : (|.q1.|) < r } as Subset of TOP-REAL n by A1,TOPREAL3:8;
  let A be Subset of Euclid n;
  for q being Point of TOP-REAL n st q in C holds |.q.|<r
  proof
    let q be Point of TOP-REAL n;
    assume q in C;
    then ex q1 being Point of TOP-REAL n st q1=q & (|.q1.|) < r;
    hence thesis;
  end;
  then
A2: C is bounded by Th21;
  assume A={q1 : (|.q1.|) < r };
  hence thesis by A2,Th5;
end;
