reserve x for set,
  D for non empty set,
  k,n,m,i,j,l for Nat,
  K for Field;

theorem Th67:
  for K being Field, A being Matrix of K holds A*(1.(K,width A))=A
proof
  let K be Field, A be Matrix of K;
  set n=width A;
  set B=1.(K,n);
A1: width B=n by MATRIX_0:24;
A2: len B=n by MATRIX_0:24;
  then
A3: width (A*B)=width B by MATRIX_3:def 4;
A4: now
    let i,j be Nat;
    assume
A5: [i,j] in Indices (A*B);
    then
A6: j in Seg width B by A3,ZFMISC_1:87;
    then j in Seg len (Line(A,i)) by A1,MATRIX_0:def 7;
    then
A7: j in dom (Line(A,i)) by FINSEQ_1:def 3;
A8: now
      let k be Nat;
      assume that
A9:   k in dom (Col(B,j)) and
A10:  k<>j;
      k in Seg len (Col(B,j)) by A9,FINSEQ_1:def 3;
      then k in Seg len B by MATRIX_0:def 8;
      then k in dom B by FINSEQ_1:def 3;
      then [k,j] in Indices B by A6,ZFMISC_1:87;
      hence (Col(B,j)).k=0.K by A10,MATRIX_3:16;
    end;
A11: j in Seg width A by A1,A3,A5,ZFMISC_1:87;
    then j in dom B by A2,FINSEQ_1:def 3;
    then [j,j] in Indices B by A1,A11,ZFMISC_1:87;
    then
A12: (Col(B,j)).j=1_K by MATRIX_3:16;
    j in Seg len (Col(B,j)) by A2,A1,A6,MATRIX_0:def 8;
    then
A13: j in dom (Col(B,j)) by FINSEQ_1:def 3;
    thus (A*B)*(i,j)= Line(A,i) "*" Col(B,j) by A2,A5,MATRIX_3:def 4
      .=Col(B,j) "*" Line(A,i) by FVSUM_1:90
      .=Sum(mlt(Col(B,j),Line(A,i))) by FVSUM_1:def 9
      .=Line(A,i).j by A13,A7,A8,A12,MATRIX_3:17
      .=A*(i,j) by A11,MATRIX_0:def 7;
  end;
  len (A*B)=len A by A2,MATRIX_3:def 4;
  hence thesis by A1,A3,A4,MATRIX_0:21;
end;
