
theorem Th67:  :: ExtREAL version of RFINSEQ:9
  for R1,R2 be without-infty FinSequence of ExtREAL
    st R1,R2 are_fiberwise_equipotent
  holds Sum R1 = Sum R2
proof
  let R1,R2 be without-infty FinSequence of ExtREAL;
  defpred P[Nat] means for f,g be without-infty FinSequence of ExtREAL
   st f,g are_fiberwise_equipotent & len f = $1 holds Sum f = Sum g;
  assume
A1: R1,R2 are_fiberwise_equipotent;
A2: len R1 = len R1;
A3: for n be Nat st P[n] holds P[n+1]
  proof
    let n be Nat;
    assume
A4: P[n];
    let f,g be without-infty FinSequence of ExtREAL;
    assume that
A5: f,g are_fiberwise_equipotent and
A6: len f = n+1;
    set a = f.(n+1);
A7: rng f = rng g by A5,CLASSES1:75;
    0 qua Nat+1<=n+1 by NAT_1:13;
    then n+1 in dom f by A6,FINSEQ_3:25;
    then
A8: a in rng g by A7,FUNCT_1:def 3;
    then consider m being Nat such that
A9: m in dom g and
A10: g.m = a by FINSEQ_2:10;
    set gg = g/^m, gm = g|m;
    m<=len g by A9,FINSEQ_3:25; then
A11: len gm = m by FINSEQ_1:59;
A12: 1<=m by A9,FINSEQ_3:25;
    max(0,m-1) = m-1 by A9,FINSEQ_3:25,FINSEQ_2:4;
    then reconsider m1 = m-1 as Element of NAT by FINSEQ_2:5;
A13: m = m1+1;
    then
A14: Seg m1 c= Seg m by FINSEQ_1:5,NAT_1:11;
    m in Seg m by A12,FINSEQ_1:1;
    then gm.m = a by A9,A10,RFINSEQ:6;
    then
A15: gm = (gm|m1)^<*a*> by A11,A13,RFINSEQ:7;
    set fn = f|n;
A16: g = (g|m)^(g/^m);
A17: gm|m1 = gm|(Seg m1) by FINSEQ_1:def 16
      .= (g|(Seg m))|(Seg m1) by FINSEQ_1:def 16
      .= g|((Seg m)/\(Seg m1)) by RELAT_1:71
      .= g|(Seg m1) by A14,XBOOLE_1:28
      .= g|m1 by FINSEQ_1:def 16;
A18: f = fn ^ <*a*> by A6,RFINSEQ:7;
A19: fn is without-infty & g|m1 is without-infty
  & gg is without-infty & gm is without-infty
  & g/^m is without-infty by MEASURE9:36,Th65; then
A20: (g|m1)^gg is without-infty & (g|m1)^(g/^m) is without-infty by Th64;
    a <> -infty by A8,MESFUNC5:def 3; then
    not -infty in {a} by TARSKI:def 1; then
A21: not -infty in rng <*a*> by FINSEQ_1:38; then
A22: <*a*> is without-infty FinSequence of ExtREAL by MESFUNC5:def 3;
A23: not -infty in rng fn
  & not -infty in rng((g|m1)^gg)
  & not -infty in rng(g|m1)
  & not -infty in rng gg
  & not -infty in rng gm by A19,A20,MESFUNC5:def 3;
A24: Sum(g|m1) <> -infty & Sum <*a*> <> -infty & Sum gg <> -infty
      by A22,Th66,MEASURE9:36,Th65;
A25:now
      let x be object;
      card Coim(f,x) = card Coim(g,x) by A5,CLASSES1:def 10; then
      card (f"{x}) = card Coim(g,x) by RELAT_1:def 17; then
      card (f"{x}) = card (g"{x}) by RELAT_1:def 17;
      then
      card(fn"{x}) + card(<*a*>"{x}) = card(((g|m1)^<*a*>^(g/^m))"{x})
        by A15,A17,A18,FINSEQ_3:57
        .= card(((g|m1)^<*a*>)"{x}) + card((g/^m)"{x}) by FINSEQ_3:57
        .= card((g|m1)"{x})+ card(<*a*>"{x}) + card((g/^m)"{x}) by FINSEQ_3:57
        .= card((g|m1)"{x}) + card((g/^m)"{x})+ card(<*a*>"{x})
        .= card(((g|m1)^(g/^m))"{x})+ card(<*a*>"{x}) by FINSEQ_3:57
        .= card Coim((g|m1)^(g/^m),x) + card(<*a*>"{x}) by RELAT_1:def 17;
      hence card Coim(fn,x) = card Coim((g|m1)^(g/^m),x) by RELAT_1:def 17;
    end;
    len fn = n by A6,FINSEQ_1:59,NAT_1:11;
    then Sum fn = Sum((g|m1)^gg) by A4,A19,A20,A25,CLASSES1:def 10;
    hence Sum f = Sum((g|m1)^gg) + Sum <*a*> by A18,A23,A21,EXTREAL1:10
      .= Sum(g|m1) + Sum gg+ Sum <*a*> by A23,EXTREAL1:10
      .= Sum(g|m1)+ Sum <*a*> + Sum gg by A24,XXREAL_3:29
      .= Sum gm + Sum gg by A15,A17,A23,A21,EXTREAL1:10
      .= Sum g by A16,A23,EXTREAL1:10;
  end;
A26: P[0]
  proof
    let f,g be without-infty FinSequence of ExtREAL;
    assume f,g are_fiberwise_equipotent & len f = 0; then
A27: len g = 0 & f = <*>ExtREAL by RFINSEQ:3;
     then g = <*>ExtREAL;
    hence thesis by A27;
  end;
  for n be Nat holds P[n] from NAT_1:sch 2(A26,A3);
  hence thesis by A1,A2;
end;
