reserve i,j,k,n,m for Nat,
        X for set,
        b,s for bag of X,
        x for object;
reserve O for Ordinal,
        R for right_zeroed add-associative right_complementable
          right_unital distributive non trivial doubleLoopStr,
        p for Polynomial of O, R;
reserve O for Ordinal,
        R for right_zeroed add-associative right_complementable
             right_unital distributive non trivial doubleLoopStr,
        p for Polynomial of O, R;

theorem Th67:
  for fc be FinSequence of F_Complex, fr be FinSequence of F_Real st fc = fr
    holds Product fc = Product fr
proof
  reconsider FC = F_Complex,FR = F_Real as Field;
  defpred P[Nat]means
  for fc be FinSequence of FC,
  fr be FinSequence of FR st fc=fr & len fc =$1 holds
  Product fc = Product fr;
A1:P[0]
  proof
    let fc be FinSequence of FC,
    fr be FinSequence of FR such that
A2: fc = fr & len fc =0;
A3: fc = <*>the carrier of FC & fr = fc = <*>the carrier of FR by A2;
    hence
    Product fc = 1_FR by COMPLEX1:def 4,COMPLFLD:8,GROUP_4:8
    .= Product fr by A3,GROUP_4:8;
  end;
A4: P[n] implies P[n+1]
  proof
    assume
A5: P[n];
    set n1=n+1;
    let fc be FinSequence of FC,
    fr be FinSequence of FR such that
A6: fc = fr & len fc =n1;
    reconsider x=Product (fr|n),y=fr/.n1 as Real;
    n < n1 by NAT_1:13;
    then
A7: len (fc|n) = n =len (fr|n) by A6,FINSEQ_1:59;
    1<= n1 by NAT_1:11;
    then
A8: fc/.n1 = fc.n1 = fr/.n1 by A6,PARTFUN1:def 6,FINSEQ_3:25;
A9: fr = (fr|n)^<*fr/.n1*> &
    fc = (fc|n)^<*fc/.n1*> by A6,FINSEQ_5:21;
    hence Product fc = Product (fc|n) * fc/.n1 by GROUP_4:6
    .= multcomplex.(Product (fc|n),fc/.n1) by COMPLFLD:def 1
    .= multcomplex.(x,y) by A5,A6,A7,A8
    .= x*y by BINOP_2:def 5
    .= Product (fr|n) * fr/.n1 by BINOP_2:def 11
    .= Product fr by A9,GROUP_4:6;
  end;
  let fc be FinSequence of F_Complex,fr be FinSequence of F_Real such that
A10: fc = fr;
  P[n] from NAT_1:sch 2(A1,A4);
  then P[len fc];
  hence thesis by A10;
end;
