reserve A,B,C for Ordinal,
        o for object,
        x,y,z,t,r,l for Surreal,
        X,Y for set;

theorem Th67:
  x*(y+z) == x*y + x*z
proof
  defpred P[Ordinal] means
  for x,y,z be Surreal st
  born x (+) born y (+) born z c= $1 holds x*(y+z) == x*y + x*z;
  A1: for D be Ordinal st for C be Ordinal st C in D holds P[C] holds P[D]
  proof
    let D be Ordinal such that A2: for C be Ordinal st C in D holds P[C];
    let x,y,z such that A3:born x (+) born y (+) born z c= D;
    set xy=x*y,xz=x*z, yz=y+z;
    A4: xy = [comp(L_x,x,y,L_y) \/ comp(R_x,x,y,R_y),
    comp(L_x,x,y,R_y) \/ comp(R_x,x,y,L_y)] by Th50;
    A5: xz = [comp(L_x,x,z,L_z) \/ comp(R_x,x,z,R_z),
    comp(L_x,x,z,R_z) \/ comp(R_x,x,z,L_z)] by Th50;
    A6: yz = [(L_y ++ {z})\/({y} ++ L_z), (R_y ++ {z}) \/({y} ++ R_z)]by Th28;
    A7:x*yz = [comp(L_x,x,yz,L_yz) \/ comp(R_x,x,yz,R_yz),
    comp(L_x,x,yz,R_yz) \/ comp(R_x,x,yz,L_yz)] by Th50;
    A8: xy+xz =
    [(L_xy ++ {xz})\/({xy} ++ L_xz),(R_xy ++ {xz}) \/({xy} ++ R_xz)] by Th28;
    A9:comp(L_x,x,yz,L_yz) = comp(L_x,x,yz,L_y++{z})\/comp(L_x,x,yz,{y}++L_z)
    by A6,Th60;
    A10:comp(R_x,x,yz,L_yz) = comp(R_x,x,yz,L_y++{z})\/
      comp(R_x,x,yz,{y} ++ L_z) by A6,Th60;
    A11: comp(R_x,x,yz,R_yz) = comp(R_x,x,yz,R_y ++ {z})
    \/comp(R_x,x,yz,{y} ++ R_z) by A6,Th60;
    A12: comp(L_x,x,yz,R_yz) = comp(L_x,x,yz,R_y ++ {z})
    \/comp(L_x,x,yz,{y} ++ R_z) by A6,Th60;
    A13:for X,Z be surreal-membered set st (X=L_x or X=R_x) & (Z=L_z or Z=R_z)
    holds comp(X,x,z,Z) ++{xy}  <==> comp(X,x,yz,Z ++ {y})
    proof
      let X,Z be surreal-membered set such that
      A14: (X=L_x or X=R_x) &(Z=L_z or Z=R_z);
      for o be Surreal st o in comp(X,x,z,Z) ++{xy} ex b be Surreal st
      b in comp(X,x,yz,Z ++ {y}) & o==b
      proof
        let o be Surreal;
        assume o in comp(X,x,z,Z) ++{xy};
        then consider xz1,xy1 be Surreal such that
        A15: xz1 in comp(X,x,z,Z) & xy1 in {xy} & o = xz1 + xy1 by Def8;
        consider x1,z1 be Surreal such that
        A16:xz1 = x1 * z + x*z1 - x1*z1 & x1 in X & z1 in Z by A15,Def15;
        A17:R_x<> {x} <> L_x & R_z<>{z} <> L_z by SURREALO:2;
        A18:x in {x} & y in {y} & z in {z} by TARSKI:def 1;
        born x1 (+) born y (+) born z in born x (+) born y (+) born z
        by A14,A16,A18,A17,Lm7;
        then A19: x1 * (y+z) == x1* y + x1*z by A2,A3;
        set yz1=y+z1;
        born x (+) born y (+) born z1 in born x (+) born y (+) born z
        by A14,A18,A17,Lm7,A16;
        then A20: x*(y+z1) == x*y + x*z1 by A2,A3;
        A21: born x1 (+) born y (+) born z1 in born x (+) born y (+) born z
        by A14,A18,A17,Lm7,A16;
        A22: - (x1 * z1 + x1* y) = (- (x1 * z1)) + (- (x1* y)) by Th40;
        yz1 in {y}++Z by A18,A16,Def8;
        then A23:x1 * yz + x*yz1 - x1*yz1 in comp(X,x,yz,{y}++Z)
        by A16,Def15;
        x1*z + (x*y + x*z1) = x1*z + x*z1 + x*y by Th37;
        then A24: (x1*z + (x*y + x*z1)) + (- (x1 * z1))
        = x*y + (x1*z + x*z1 + - (x1 * z1)) by Th37;
        A25:x1* y - (x1* y)==0_No by Th39;
        A26: - x1*yz1 == ((- (x1 * z1)) + (- (x1* y))) by A22,A21,A2,A3,Th65;
        x1 * yz + x*yz1 == (x1* y + x1*z) + (x*y + x*z1) by A19,A20,Th43;
        then
        A27: x1 * yz + x*yz1 + - x1*yz1 == (x1* y + x1*z) + (x*y + x*z1)
        + ((- (x1 * z1)) + (- (x1* y))) by A26,Th43;
        (x1* y + x1*z) + (x*y + x*z1) + ((- (x1 * z1)) + (- (x1* y)))
        = (x1* y + (x1*z + (x*y + x*z1))) + ((- (x1 * z1)) + (- (x1* y)))
        by Th37
        .= ((x1* y + (x1*z + (x*y + x*z1))) + (- (x1 * z1))) + - (x1* y)
        by Th37
        .= x1* y + ((x1*z + (x*y + x*z1)) + (- (x1 * z1))) + - (x1* y) by Th37
        .= x1* y + - (x1* y) + ( (x1*z + x*z1 + - (x1 * z1)) +x*y )
        by A24,Th37;
        then x1 * yz + x*yz1 + - x1*yz1 == x1* y + - (x1* y) + o == 0_No+o = o
        by A27,A16,A15,TARSKI:def 1,A25,Th43;
        hence thesis by A23,SURREALO:10;
      end;
      hence comp(X,x,z,Z) ++{xy}  <=_ comp(X,x,yz,Z ++ {y}) by Th61;
      for o be Surreal st o in comp(X,x,yz,Z ++ {y}) ex b be Surreal st
      b in comp(X,x,z,Z) ++{xy} & o==b
      proof
        let o be Surreal;
        assume o in comp(X,x,yz,Z ++ {y});
        then consider x1,yz1 be Surreal such that
        A28: o = x1 * yz + x*yz1 - x1*yz1 & x1 in X & yz1 in Z ++ {y}
        by Def15;
        consider z1,y1 be Surreal such that
        A29: z1 in Z & y1 in {y} & yz1 = z1 + y1 by A28,Def8;
        A30: y1=y by A29,TARSKI:def 1;
        A31: R_x<> {x} <> L_x & R_z<>{z} <> L_z by SURREALO:2;
        A32: x in {x} & y in {y} & z in {z} by TARSKI:def 1;
        born x1 (+) born y (+) born z in born x (+) born y (+) born z
        by A14,A32,A31,A28,Lm7;
        then A33: x1 * (y+z) == x1* y + x1*z by A2,A3;
        born x (+) born y1 (+) born z1 in born x (+) born y (+) born z
        by A14,A32,A31,Lm7,A29;
        then A34: x*yz1 == x*y + x*z1 by A2,A3,A29,A30;
        born x1 (+) born y1 (+) born z1 in born x (+) born y (+) born z
        by A14,A31,A28,Lm7,A29;
        then A35: x1*yz1 == x1*z1 + x1*y by A2,A3,A29,A30;
        A36: x1* z + x*z1  - (x1 * z1) in comp(X,x,z,Z) by A28,A29,Def15;
        xy in {xy} by TARSKI:def 1;
        then A37: (x1* z + x*z1 + - (x1 * z1))+xy in comp(X,x,z,Z) ++{xy}
        by A36,Def8;
        x1* y  - (x1* y) ==0_No by Th39;
        then A38: x1* y + - (x1* y) + ( (x1*z + x*z1 + - (x1 * z1)) +x*y )
        == 0_No + ( (x1*z + x*z1 + - (x1 * z1)) +x*y ) by Th43;
        x1*z + (x*y + x*z1) = x1*z + x*z1 + x*y by Th37;
        then A39: (x1*z + (x*y + x*z1)) + (- (x1 * z1))
        = x*y + (x1*z + x*z1 + - (x1 * z1)) by Th37;
        - x1*yz1 == - (x1*z1 + x1*y) by A35,Th10;
        then A40:- x1*yz1 == (- (x1 * z1)) + (- (x1* y)) by Th40;
        x1 * yz + x*yz1 == (x1* y + x1*z) + (x*y + x*z1)
        by A33,A34,Th43;
        then A41:o == (x1* y + x1*z) + (x*y + x*z1) +
        ((- (x1 * z1)) + (- (x1* y))) by A40,A28,Th43;
        (x1* y + x1*z) + (x*y + x*z1) + ((- (x1 * z1)) + (- (x1* y)))
        = (x1* y + (x1*z + (x*y + x*z1))) + ((- (x1 * z1)) + (- (x1* y)))
        by Th37
        .= ((x1* y + (x1*z + (x*y + x*z1))) + (- (x1 * z1))) + - (x1* y)
        by Th37
        .= x1* y + ((x1*z + (x*y + x*z1)) + (- (x1 * z1))) + - (x1* y) by Th37
        .= x1* y + -(x1* y) + ( (x1*z + x*z1 + - (x1 * z1)) +x*y)by A39,Th37;
        then o == 0_No + ((x1*z + x*z1 + - (x1 * z1)) +x*y)
        by A41,A38,SURREALO:4;
        hence thesis by A37;
      end;
      hence thesis by  Th61;
    end;
    A42:for X,Y be surreal-membered set st (X=L_x or X=R_x) & (Y=L_y or Y=R_y)
    holds comp(X,x,y,Y) ++{xz} <==> comp(X,x,yz,Y ++ {z})
    proof
      let X,Y be surreal-membered set such that
      A43: (X=L_x or X=R_x) & (Y=L_y or Y=R_y);
      for o be Surreal st o in comp(X,x,y,Y) ++{xz} ex b be Surreal st
      b in comp(X,x,yz,Y ++ {z}) & o==b
      proof
        let o be Surreal;
        assume o in comp(X,x,y,Y) ++{xz};
        then consider xy1,xz1 be Surreal such that
        A44: xy1 in comp(X,x,y,Y) & xz1 in {xz} & o = xy1 + xz1 by Def8;
        consider x1,y1 be Surreal such that
        A45:xy1 = x1 * y + x*y1 - x1*y1 & x1 in X & y1 in Y
        by A44,Def15;
        A46: xz1=xz by A44,TARSKI:def 1;
        A47: (x1* y + x1*z) + (x*y1 + x*z)=x1* y + (x1*z + (x*z + x*y1))
        by Th37
        .=x1* y + ((x1*z + x*z) + x*y1) by Th37
        .=(x1* y + x*y1) +(x1*z + x*z) by Th37;
        A48: R_x<> {x} <> L_x & R_y<>{y} <> L_y by SURREALO:2;
        A49: x in {x} & y in {y} & z in {z} by TARSKI:def 1;
        born x1 (+) born y (+) born z in born x (+) born y (+) born z
        by A43,A45,A49,A48,Lm7;
        then A50: x1 * (y+z) == x1* y + x1*z by A2,A3;
        set yz1=y1+z;
        born x (+) born y1 (+) born z in born x (+) born y (+) born z
        by A43,A49,A48,Lm7,A45;
        then A51: x*(y1+z) == x*y1 + x*z by A2,A3;
        A52: born x1 (+) born y1 (+) born z in born x (+) born y (+) born z
        by A43,A49,A48,Lm7,A45;
        x1*z - (x1* z) ==0_No by Th39;
        then A53:  x*z+(x1*z + - (x1* z)) == x*z+0_No =x *z by Th43;
        ( x*z+x1*z) + (- (x1* z)) == x*z by A53,Th37;
        then A54:( x*z+x1*z) + (- (x1* z)) +(- (x1 * y1)) == x*z +- (x1 * y1)
        by Th43;
        A55: (x1* y + x*y1) + (x*z +- (x1 * y1))
        = x1* y + (x*y1 + (- (x1 * y1)+x*z)) by Th37
        .= x1* y + ((x*y1 + - (x1 * y1))+x*z) by Th37
        .= x1* y + (x*y1 + - (x1 * y1))+x*z by Th37
        .= (x1* y + x*y1 + - (x1 * y1))+x*z by Th37;
        A56: - (x1 * y1 + x1* z) = (- (x1 * y1)) + (- (x1* z)) by Th40;
        yz1 in Y++{z} by A49,A45,Def8;
        then A57:x1 * yz + x*yz1 -x1*yz1 in comp(X,x,yz,Y++{z}) by A45,Def15;
        A58: - x1*yz1 == (- (x1* z)) +(- (x1 * y1))
        by A52,A2,A3,Th65,A56;
        x1 * yz + x*yz1 == (x1* y + x*y1) + ( x*z+x1*z) by A47,A50,A51,Th43;
        then x1 * yz + x*yz1 + - x1*yz1 ==
        (x1* y + x*y1) + ( x*z+x1*z)+((- (x1* z)) +(- (x1 * y1))) by A58,Th43;
        then x1 * yz + x*yz1 + - x1*yz1 ==
        (x1* y + x*y1) + (( x*z+x1*z) + ( (- (x1* z)) +(- (x1 * y1))))by Th37;
        then A59:x1 * yz + x*yz1 + - x1*yz1 ==
        (x1* y + x*y1) + ((( x*z+x1*z) + (- (x1* z))) +(- (x1 * y1)))by Th37;
        (x1* y + x*y1) + ((( x*z+x1*z) + (- (x1* z))) +(- (x1 * y1))) ==
        (x1* y + x*y1) + (x*z +- (x1 * y1)) by A54,Th43;
        hence thesis by A57,A44,A46,A55,A45,A59,SURREALO:10;
      end;
      hence comp(X,x,y,Y) ++{xz} <=_ comp(X,x,yz,Y ++ {z}) by Th61;
      for o be Surreal st o in comp(X,x,yz,Y ++ {z})
      ex b be Surreal st b in comp(X,x,y,Y) ++{xz} & o==b
      proof
        let o be Surreal;
        assume  o in comp(X,x,yz,Y ++ {z});
        then consider x1,yz1 be Surreal such that
        A60:o = x1 * yz + x*yz1 - x1*yz1 & x1 in X & yz1 in Y ++ {z}
        by Def15;
        consider y1,z1 be Surreal such that
        A61: y1 in Y & z1 in {z} & yz1 = y1 + z1 by A60,Def8;
        A62: z1=z by A61,TARSKI:def 1;
        A63: (x1* y + x1*z) + (x*y1 + x*z)
        =x1* y + (x1*z + (x*z + x*y1)) by Th37
        .=x1* y + ((x1*z + x*z) + x*y1) by Th37
        .=(x1* y + x*y1) +(x1*z + x*z) by Th37;
        A64: R_x<> {x} <> L_x & R_y<>{y} <> L_y by SURREALO:2;
        A65: x in {x} & y in {y} & z in {z} by TARSKI:def 1;
        born x1 (+) born y (+) born z in born x (+) born y (+) born z
        by A43,A65,A64,A60,Lm7;
        then A66: x1 * (y+z) == x1* y + x1*z by A2,A3;
        born x (+) born y1 (+) born z1 in born x (+) born y (+) born z
        by A43,A65,A64,Lm7,A61;
        then A67: x*yz1 == x*y1 + x*z by A2,A3,A61,A62;
        A68: born x1 (+) born y1 (+) born z1 in born x (+) born y (+) born z
        by A43,A64,A60,Lm7,A61;
        A69: x1*z - (x1* z) ==0_No by Th39;
        A70: x1* y + x*y1 - (x1 * y1) in comp(X,x,y,Y) by A60,A61,Def15;
        xz in {xz} by TARSKI:def 1;
        then A71: (x1* y + x*y1 + - (x1 * y1))+xz in comp(X,x,y,Y) ++{xz}
        by A70,Def8;
        A72: (x1* y + x*y1) + (x*z +- (x1 * y1))
        = x1* y + (x*y1 + (- (x1 * y1)+x*z)) by Th37
        .= x1* y + ((x*y1 + - (x1 * y1))+x*z) by Th37
        .= x1* y + (x*y1 + - (x1 * y1))+x*z by Th37
        .= (x1* y + x*y1 + - (x1 * y1))+x*z by Th37;
        A73: - (x1 * y1 + x1* z) = (- (x1 * y1)) + (- (x1* z)) by Th40;
        A74:- x1*yz1 == (- (x1* z)) +(- (x1 * y1))
        by A73,A68,A2,A3,A61,A62,Th65;
        A75: x1 * yz + x*yz1 == (x1* y + x*y1) +(x*z+x1*z)
        by A66,A67,A63,Th43;
        A76: o == (x1* y + x*y1) +(x*z+x1*z) +((- (x1* z)) +(- (x1 * y1)))
        by A60,Th43,A74,A75;
        A77: (x1* y + x*y1) +(x*z+x1*z) +((- (x1* z)) +(- (x1 * y1)))
        = (x1* y + x*y1) + (( x*z+x1*z) + ( (- (x1* y1)) +(- (x1 * z))))
        by Th37
        .=(x1* y + x*y1) + ( (( x*z+x1*z) +  - (x1* y1)) +(- (x1 * z)))
        by Th37
        .=(x1* y + x*y1) + ( (( x*z+ - (x1* y1) +x1*z )) +(- (x1 * z)))
        by Th37
        .=(x1* y + x*y1) + ( ( x*z+ - (x1* y1)) +(x1*z  +(- (x1 * z))))
        by Th37
        .= ((x1* y + x*y1 + - (x1 * y1))+x*z)+(( (x1* z)) +(- (x1 * z)))
        by A72,Th37;
        ((x1* y + x*y1 + - (x1 * y1))+x*z)+(( (x1* z)) +(- (x1 * z))) ==
        ((x1* y + x*y1 + - (x1 * y1))+x*z)+0_No by A69,Th43;
        hence thesis by A76,SURREALO:10,A71,A77;
      end;
      hence thesis by Th61;
    end;
    A78: comp(L_x,x,yz,L_y ++ {z}) <==> comp(L_x,x,y,L_y) ++{xz} by A42;
    comp(L_x,x,yz,{y} ++ L_z) <==> comp(L_x,x,z,L_z) ++{xy} by A13;
    then A79: comp(L_x,x,yz,L_yz) <==> (comp(L_x,x,y,L_y) ++{xz})
    \/(comp(L_x,x,z,L_z) ++{xy}) by A78,SURREALO:31,A9;
    A80:comp(R_x,x,yz,R_y ++ {z}) <==> comp(R_x,x,y,R_y) ++{xz} by A42;
    comp(R_x,x,yz,{y} ++ R_z) <==> comp(R_x,x,z,R_z) ++{xy} by A13;
    then A81: comp(R_x,x,yz,R_yz) <==> (comp(R_x,x,y,R_y) ++{xz})
    \/(comp(R_x,x,z,R_z) ++{xy}) by A80,SURREALO:31,A11;
    ((comp(L_x,x,y,L_y) ++{xz}) \/(comp(L_x,x,z,L_z) ++{xy})) \/
    ((comp(R_x,x,y,R_y) ++{xz})\/(comp(R_x,x,z,R_z) ++{xy})) =
    (((comp(L_x,x,y,L_y) ++{xz}) \/(comp(L_x,x,z,L_z) ++{xy})) \/
    (comp(R_x,x,z,R_z) ++{xy}))\/ (comp(R_x,x,y,R_y) ++{xz}) by XBOOLE_1:4
    .= (   (comp(L_x,x,y,L_y) ++{xz}) \/((comp(L_x,x,z,L_z) ++{xy})
    \/ (comp(R_x,x,z,R_z) ++{xy})))
    \/ (comp(R_x,x,y,R_y) ++{xz}) by XBOOLE_1:4
    .= ((comp(L_x,x,y,L_y) ++{xz}) \/ (comp(R_x,x,y,R_y) ++{xz})) \/
    ((comp(L_x,x,z,L_z) ++{xy}) \/ (comp(R_x,x,z,R_z) ++{xy})) by XBOOLE_1:4
    .= ( ( comp(L_x,x,y,L_y) \/ comp(R_x,x,y,R_y)) ++{xz}) \/
    ((comp(L_x,x,z,L_z) ++{xy}) \/ (comp(R_x,x,z,R_z) ++{xy})) by Th33
    .= (xy+xz)`1 by A8,Th33,A5,A4;
    then A82: L_(x*yz) <==> L_(xy+xz) by A81,A7,A79,SURREALO:31;
    A83: comp(L_x,x,yz,R_y ++ {z}) <==> comp(L_x,x,y,R_y) ++{xz} by A42;
    comp(L_x,x,yz,{y} ++ R_z) <==> comp(L_x,x,z,R_z) ++{xy} by A13;
    then A84: comp(L_x,x,yz,R_yz) <==> (comp(L_x,x,y,R_y) ++{xz})
    \/(comp(L_x,x,z,R_z) ++{xy}) by A83,SURREALO:31,A12;
    A85:comp(R_x,x,yz,L_y ++ {z}) <==> comp(R_x,x,y,L_y) ++{xz} by A42;
    comp(R_x,x,yz,{y} ++ L_z) <==> comp(R_x,x,z,L_z) ++{xy} by A13;
    then A86:comp(R_x,x,yz,L_yz) <==> (comp(R_x,x,y,L_y) ++{xz})
    \/(comp(R_x,x,z,L_z) ++{xy})
    by A85,SURREALO:31,A10;
    A87: R_(x*yz)<==>((comp(L_x,x,y,R_y) ++{xz})\/(comp(L_x,x,z,R_z) ++{xy}))\/
     ((comp(R_x,x,y,L_y) ++{xz})\/(comp(R_x,x,z,L_z) ++{xy}))
     by A7,A84,A86,SURREALO:31;
    ((comp(L_x,x,y,R_y) ++{xz})\/(comp(L_x,x,z,R_z) ++{xy}))\/
    ((comp(R_x,x,y,L_y) ++{xz})\/(comp(R_x,x,z,L_z) ++{xy}))=
    (((comp(L_x,x,y,R_y) ++{xz})\/(comp(L_x,x,z,R_z) ++{xy}))\/
    (comp(R_x,x,z,L_z) ++{xy})) \/ (comp(R_x,x,y,L_y) ++{xz}) by XBOOLE_1:4
    .=((comp(L_x,x,y,R_y) ++{xz}) \/((comp(L_x,x,z,R_z) ++{xy})\/
    (comp(R_x,x,z,L_z) ++{xy}))) \/ (comp(R_x,x,y,L_y) ++{xz}) by XBOOLE_1:4
    .= ( (comp(L_x,x,y,R_y) ++{xz}) \/(comp(R_x,x,y,L_y) ++{xz}))
    \/ ((comp(L_x,x,z,R_z) ++{xy})\/(comp(R_x,x,z,L_z) ++{xy})) by XBOOLE_1:4
    .=((comp(L_x,x,y,R_y) \/comp(R_x,x,y,L_y)) ++{xz})
    \/ ((comp(L_x,x,z,R_z) ++{xy})\/(comp(R_x,x,z,L_z) ++{xy})) by Th33
    .= (xy+xz)`2 by Th33,A8,A4,A5;
    hence thesis by A87,A7,A8,A82,SURREALO:29;
  end;
  for D be Ordinal holds P[D] from ORDINAL1:sch 2(A1);
  then P[born x (+) born y (+) born z];
  hence thesis;
end;
