reserve
  S for (4,1) integer bool-correct non empty non void BoolSignature,
  X for non-empty ManySortedSet of the carrier of S,
  T for vf-free integer all_vars_including inheriting_operations free_in_itself
  (X,S)-terms VarMSAlgebra over S,
  C for (4,1) integer bool-correct non-empty image of T,
  G for basic GeneratorSystem over S,X,T,
  A for IfWhileAlgebra of the generators of G,
  I for integer SortSymbol of S,
  x,y,z,m for pure (Element of (the generators of G).I),
  b for pure (Element of (the generators of G).the bool-sort of S),
  t,t1,t2 for Element of T,I,
  P for Algorithm of A,
  s,s1,s2 for Element of C-States(the generators of G);
reserve
  f for ExecutionFunction of A, C-States(the generators of G),
  (\falseC)-States(the generators of G, b);
reserve u for ManySortedFunction of FreeGen T, the Sorts of C;

theorem Th68:
  A is elementary implies
  for a being SortSymbol of S
  for x being Element of (the generators of G).a
  for t being Element of T,a holds
  x:=(t,A) in ElementaryInstructions A
  proof assume
A1: rng the assignments of A c= ElementaryInstructions A;
    let a be SortSymbol of S;
    let x be Element of (the generators of G).a;
    let t be Element of T,a;
    [x,t] in [:(the generators of G).a,(the Sorts of T).a:] by ZFMISC_1:87;
    then [x,t] in [|the generators of G, the Sorts of T|].a &
    dom [|the generators of G, the Sorts of T|] = the carrier of S
    by PARTFUN1:def 2,PBOOLE:def 16;
    then x:=(t,A) in rng the assignments of A by FUNCT_2:4,CARD_5:2;
    hence thesis by A1;
   end;
