reserve x,y for set;
reserve C,C9,D,D9,E for non empty set;
reserve c for Element of C;
reserve c9 for Element of C9;
reserve d,d1,d2,d3,d4,e for Element of D;
reserve d9 for Element of D9;
reserve i,j for natural Number;
reserve F for Function of [:D,D9:],E;
reserve p,q for FinSequence of D,
  p9,q9 for FinSequence of D9;
reserve f,f9 for Function of C,D,
  h for Function of D,E;
reserve T,T1,T2,T3 for Tuple of i,D;
reserve T9 for Tuple of i, D9;
reserve S for Tuple of j, D;
reserve S9 for Tuple of j, D9;
reserve F,G for BinOp of D;
reserve u for UnOp of D;
reserve H for BinOp of E;

theorem
  F is having_a_unity & F is associative & F is having_an_inverseOp &
  u = the_inverseOp_wrt F & G is_distributive_wrt F & G is having_a_unity
  implies G [;](u.(the_unity_wrt G),id D) = u
proof
  assume that
A1: F is having_a_unity & F is associative & F is having_an_inverseOp &
  u = the_inverseOp_wrt F & G is_distributive_wrt F and
A2: G is having_a_unity;
  set o = the_unity_wrt G;
  for d holds (G[;](u.o,id D)).d = u.d
  proof
    let d;
    thus (G[;](u.o,id D)).d = G.(u.o,(id D).d) by FUNCOP_1:53
      .= G.(u.o,d)
      .= u.(G.(o,d)) by A1,Th67
      .= u.d by A2,SETWISEO:15;
  end;
  hence thesis by FUNCT_2:63;
end;
