reserve n,m for Element of NAT;
reserve r,s for Real;
reserve z for Complex;
reserve CNS,CNS1,CNS2 for ComplexNormSpace;
reserve RNS for RealNormSpace;
reserve X,X1 for set;

theorem Th68:
  for f be PartFunc of CNS1,CNS2 st f is_continuous_on X holds z
  (#)f is_continuous_on X
proof
  let f be PartFunc of CNS1,CNS2;
  assume
A1: f is_continuous_on X;
  then
A2: X c= dom f;
  then
A3: X c= dom(z(#)f) by VFUNCT_2:def 2;
  now
    let s1 be sequence of CNS1;
    assume that
A4: rng s1 c= X and
A5: s1 is convergent and
A6: lim s1 in X;
A7: f/*s1 is convergent by A1,A4,A5,A6,Th41;
    then
A8: z*(f/*s1) is convergent by CLVECT_1:116;
    f/.(lim s1) = lim (f/*s1) by A1,A4,A5,A6,Th41;
    then (z(#)f)/.(lim s1) = z * lim (f/*s1) by A3,A6,VFUNCT_2:def 2
      .= lim (z*(f/*s1)) by A7,CLVECT_1:122
      .= lim ((z(#)f)/*s1) by A2,A4,Th26,XBOOLE_1:1;
    hence
    (z(#)f)/*s1 is convergent & (z(#)f)/.(lim s1)=lim((z(#)f)/*s1) by A2,A4,A8
,Th26,XBOOLE_1:1;
  end;
  hence thesis by A3,Th41;
end;
