reserve p,p1,p2,p3,q,q1,q2 for Point of TOP-REAL 2,
  i for Nat,
  lambda for Real;

theorem Th69:
  for p being Point of TOP-REAL 2,
  P being non empty compact Subset of TOP-REAL 2,
  f being Function of TOP-REAL 2,TOP-REAL 2 st
  f=Sq_Circ
  holds (f.p)`2>=0 iff p`2>=0
proof
  let p be Point of TOP-REAL 2, P be non empty compact Subset of TOP-REAL 2,
  f be Function of TOP-REAL 2,TOP-REAL 2;
  assume
A1: f=Sq_Circ;
  thus (f.p)`2>=0 implies p`2>=0
  proof
    assume
A2: (f.p)`2>=0;
    reconsider g=(Sq_Circ") as Function
    of TOP-REAL 2,TOP-REAL 2 by JGRAPH_3:29;
A3: dom f = the carrier of TOP-REAL 2 by FUNCT_2:def 1;
    set q=(f.p);
    now per cases;
      case q=0.TOP-REAL 2;
        hence (g.q)`2>=0 by A2,JGRAPH_3:28;
      end;
      case
A4:     q<> 0.TOP-REAL 2;
        now per cases;
          case q`2<=q`1 & -q`1<=q`2 or q`2>=q`1 & q`2<=-q`1;
            then
A5:         g.q=|[q`1*sqrt(1+(q`2/q`1)^2),q`2*sqrt(1+(q`2/q`1)^2)]|
            by A4,JGRAPH_3:28;
            (q`2/q`1)^2 >=0 by XREAL_1:63;
            then sqrt(1+(q`2/q`1)^2)>0 by SQUARE_1:25;
            hence (g.q)`2>=0 by A2,A5,EUCLID:52;
          end;
          case not (q`2<=q`1 & -q`1<=q`2 or q`2>=q`1 & q`2<=-q`1);
            then
A6:         g.q=|[q`1*sqrt(1+(q`1/q`2)^2),q`2*sqrt(1+(q`1/q`2)^2)]|
            by JGRAPH_3:28;
            (q`1/q`2)^2 >=0 by XREAL_1:63;
            then sqrt(1+(q`1/q`2)^2)>0 by SQUARE_1:25;
            hence (g.q)`2>=0 by A2,A6,EUCLID:52;
          end;
        end;
        hence (g.q)`2>=0;
      end;
    end;
    hence thesis by A1,A3,FUNCT_1:34;
  end;
  thus p`2>=0 implies (f.p)`2>=0
  proof
    assume
A7: p`2>=0;
    now per cases;
      case p=0.TOP-REAL 2;
        hence thesis by A1,A7,JGRAPH_3:def 1;
      end;
      case
A8:     p<> 0.TOP-REAL 2;
        now per cases;
          case p`2<=p`1 & -p`1<=p`2 or p`2>=p`1 & p`2<=-p`1;
            then
A9:         f.p=|[p`1/sqrt(1+(p`2/p`1)^2),p`2/sqrt(1+(p`2/p`1)^2)]|
            by A1,A8,JGRAPH_3:def 1;
            (p`2/p`1)^2 >=0 by XREAL_1:63;
            then sqrt(1+(p`2/p`1)^2)>0 by SQUARE_1:25;
            hence thesis by A7,A9,EUCLID:52;
          end;
          case not (p`2<=p`1 & -p`1<=p`2 or p`2>=p`1 & p`2<=-p`1);
            then
A10:        f.p=|[p`1/sqrt(1+(p`1/p`2)^2),p`2/sqrt(1+(p`1/p`2)^2)]|
            by A1,A8,JGRAPH_3:def 1;
            (p`1/p`2)^2 >=0 by XREAL_1:63;
            then sqrt(1+(p`1/p`2)^2)>0 by SQUARE_1:25;
            hence thesis by A7,A10,EUCLID:52;
          end;
        end;
        hence thesis;
      end;
    end;
    hence thesis;
  end;
end;
