reserve m,n,i,i2,j for Nat,
  r,r1,r2,s,t for Real,
  x,y,z for object;
reserve p,p1,p2,p3,q,q1,q2,q3,q4 for Point of TOP-REAL n;
reserve u for Point of Euclid n;

theorem Th54:
  for a being Real, P being Subset of TOP-REAL n st P={q : (|.q.|)
  < a } holds P is convex
proof
  let a be Real, P be Subset of TOP-REAL n;
  assume
A1: P={q : (|.q.|) < a };
  for p1,p2 being Point of TOP-REAL n st p1 in P & p2 in P holds LSeg(p1,
  p2) c= P
  proof
    let p1,p2 be Point of TOP-REAL n;
    assume that
A2: p1 in P and
A3: p2 in P;
A4: ex q2 st q2=p2 & (|.q2.|) < a by A1,A3;
A5: ex q1 st q1=p1 & (|.q1.|) < a by A1,A2;
    LSeg(p1,p2) c= P
    proof
      let x be object;
      assume
A6:   x in LSeg(p1,p2);
      then consider r such that
A7:   x=(1-r)*p1+r*p2 and
A8:   0<=r and
A9:   r<=1;
A10:  |.(1-r)*p1.|=|.1-r.|*|.p1.| by TOPRNS_1:7;
      reconsider q=x as Point of TOP-REAL n by A6;
A11:  |.(1-r)*p1+r*p2.|<=|.(1-r)*p1.|+|.r*p2.| by TOPRNS_1:29;
A12:  1-r>=0 by A9,XREAL_1:48;
      then
A13:  |.1-r.|=1-r by ABSVALUE:def 1;
      per cases;
      suppose
A14:    1-r>0;
A15:    |.r*p2.|=|.r.|*|.p2.| & r=|.r.| by A8,ABSVALUE:def 1,TOPRNS_1:7;
        0<=|.r.| by COMPLEX1:46;
        then
A16:    |.r.|*|.p2.|<=|.r.|*a by A4,XREAL_1:64;
        |.1-r.|*|.p1.|<|.1-r.|*a by A5,A13,A14,XREAL_1:68;
        then |.(1-r)*p1.|+|.r*p2.|<(1-r)*a+r*a by A10,A13,A16,A15,XREAL_1:8;
        then (|.q.|)<a by A7,A11,XXREAL_0:2;
        hence thesis by A1;
      end;
      suppose
        1-r<=0;
        then 1-r+r=0+r by A12;
        then 0<|.r.| by ABSVALUE:def 1;
        then
A17:    |.r.|*|.p2.|<|.r.|*a by A4,XREAL_1:68;
A18:    r=|.r.| by A8,ABSVALUE:def 1;
        |.1-r.|*|.p1.|<=|.1-r.|*a & |.r*p2.|=|.r.|*|.p2.| by A5,A12,A13,
TOPRNS_1:7,XREAL_1:64;
        then |.(1-r)*p1.|+|.r*p2.|<(1-r)*a+r*a by A10,A13,A17,A18,XREAL_1:8;
        then (|.q.|)<a by A7,A11,XXREAL_0:2;
        hence thesis by A1;
      end;
    end;
    hence thesis;
  end;
  hence thesis by JORDAN1:def 1;
end;
