reserve n,m for Nat,
  r,r1,r2,s,t for Real,
  x,y for set;

theorem Th69:
  for D be non empty set, F be PartFunc of D,REAL, d be Element of
  D st d in dom F holds FinS(F,{d}) = <* F.d *>
proof
  let D be non empty set, F be PartFunc of D,REAL, d be Element of D;
  assume d in dom F;
  then {d} c= dom F by ZFMISC_1:31;
  then
A1: {d} = dom F /\ {d} by XBOOLE_1:28
    .= dom(F|{d}) by RELAT_1:61;
  then FinS(F,{d}), F|{d} are_fiberwise_equipotent by Def13;
  then
A2: rng FinS(F,{d}) = rng(F|{d}) by CLASSES1:75;
A3: rng(F|{d}) = {F.d}
  proof
    thus rng(F|{d}) c= {F.d}
    proof
      let x be object;
      assume x in rng(F|{d});
      then consider e be Element of D such that
A4:   e in dom(F|{d}) and
A5:   (F|{d}).e = x by PARTFUN1:3;
      e=d by A1,A4,TARSKI:def 1;
      then x=F.d by A4,A5,FUNCT_1:47;
      hence thesis by TARSKI:def 1;
    end;
    let x be object;
A6: d in dom(F|{d}) by A1,TARSKI:def 1;
    assume x in {F.d};
    then x=F.d by TARSKI:def 1;
    then x=(F|{d}).d by A6,FUNCT_1:47;
    hence thesis by A6,FUNCT_1:def 3;
  end;
  len FinS(F,{d}) = card {d} by A1,Th67
    .= 1 by CARD_1:30;
  hence thesis by A2,A3,FINSEQ_1:39;
end;
